Question

I am new to VB.Net
My old VB 6 code is:

Set conn = my connection string
conn.open
Set ce = conn.Execute("select * from table where id = 1")
If ce.EOF Then conn.Execute ("insert into table set name = '" & Text1.Text & "'")

I want get sql table field and if eof then add record using VB.NET. Thanks for help.

Answer 1

Your old vb6 code was awful: it was vulnerable to sql injection, and badly inefficient because there’s no need to ever bring the results back to the client. There’s no excuse for either of those, even in vb6. Let’s fix both those issues with your vb.net migration. Your new code should look like this:

Public Sub InsertName(ByVal Name As String)
    'This sql code will update your database in the same way as your original, but
    ' will do so faster because you only need to make one call to the database
    ' and you never need to read any data back to the client
    Dim sql As String = _
        "INSERT INTO Table (Name) " & _ 
           " SELECT @Name WHERE NOT EXISTS (select * from table where id = 1)"

    'The using blockwill make sure the connection is closed, even if an exception is thrown
    Using cn As New SqlConnection("My connection string"), _
          cmd As New SqlCommand(sql, cn)

        'Query parameters are the ONLY acceptable way to substitute data in your sql statements
        'NEVER use string concatenation. This is IMPORTANT
        'I have to guess at your column type here. Use the actual column type in your own code
        cmd.Parameters.Add("@Name", SqlDbType.NVarChar, 50).Value = Name

        cn.Open()
        cmd.ExecuteNonQuery()
    End Using
End Sub

And then call the function like this:

InsertName(Text1.Text)

Note that most of the techniques I showed in this code were also available and the best practice in vb6 — namely the better sql and query parameters — even if the way you go about them looked different in vb6.