Question

I am quite new to XPath so bear with me. I have a XPath expression

'.//*[contains(.,"Obama")]/text()'

that gets me the text that contains “Obama”. However, I haven’t been able to figure out how to add

and [not(contains(., "Romney"))] to the expression without getting a syntax error. How is it done? Help much appriciated!

Answer 1

Use:

.//*[contains(.,"Obama") and not(contains(.,"Romney"))]/text()

XSLT – based verification:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/">
     <xsl:copy-of select=
     './/*[contains(.,"Obama") and not(contains(.,"Romney"))]/text()'/>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the following XML document:

<election>
 <choice>Maybe  Obama</choice>
 <choice>Maybe Romney</choice>
</election>

the XPath expression is evaluated and the selected node is copied to the output:

Maybe  Obama

Do note:

SomeExpression[x][y]

is not always equivalent to:

SomeExpression[x and y]

Therefore, it is recommended the latter — not the former, as specified in the answer by @ChrisGerken.

Here is a concrete example:

Let’s have this XML document:

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

and these two XPath expressions:

/*/*[. mod 3 = 0 and position() = 3]

and

/*/*[. mod 3 = 0][position() = 3]

The first expression selects:

<num>03</num>

However, the second expression selects:

<num>09</num>

And here is a complete XSLT – based verification:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:copy-of select=
     "/*/*[. mod 3 = 0 and position() = 3]"/>
     ================
     <xsl:copy-of select=
     "/*/*[. mod 3 = 0][position() = 3]"/>

 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the above XML document, the two XPath expressions are evaluated and the results of these evaluations are copied to the output:

<num>03</num>
================
<num>09</num>

Explanation:

position() is a *context-sensitive` function and typically produces different results when used in the k-th and in the m-th predicate, where k != m