Question

I am reviewing for a test and I can’t seem to get this example to code out right.

Problem: Write a perl script, called ileaf, which will linterleave the lines of a file with those of another file writing the result to a third file. If the files are a different length then the excess lines are written at the end.

A sample invocation:
ileaf file1 file2 outfile

This is what I have:

#!/usr/bin/perl -w

open(file1, "$ARGV[0]");
open(file2, "$ARGV[1]");
open(file3, ">$ARGV[2]");

while(($line1 = <file1>)||($line2 = <file2>)){
    if($line1){
            print $line1;
    }

    if($line2){
            print $line2;
    }
}

This sends the information to screen so I can immediately see the result. The final verson should “print file3 $line1;” I am getting all of file1 then all of file2 w/out and interleaving of the lines.

If I understand correctly, this is a function of the use of the “||” in my while loop. The while checks the first comparison and if it’s true drops into the loop. Which will only check file1. Once file1 is false then the while checks file2 and again drops into the loop.

What can I do to interleave the lines?

Answer 1

You’re not getting what you want from while(($line1 = <file1>)||($line2 = <file2>)){ because as long as ($line1 = <file1>) is true, ($line2 = <file2>) never happens.

Try something like this instead:

open my $file1, "<", $ARGV[0] or die;
open my $file2, "<", $ARGV[1] or die;
open my $file3, ">", $ARGV[2] or die;

while (my $f1 = readline ($file1)) {
  print $file3 $f1;  #line from file1

  if (my $f2 = readline ($file2)) {  #if there are any lines left in file2
    print $file3 $f2;
  }
}

while (my $f2 = readline ($file2)) {   #if there are any lines left in file2
  print $file3 $f2;
}

close $file1;
close $file2;
close $file3;