Question

I am switching to Twitter Bootstrap 2.1.1.

I have a modal with a button to delete but it does not work. In previous bootstrap version it worked OK. Rails version is 3.1

Here is the code

<a title="<%= t('delete') %>" id="delete" class="label" href="#myModal-<%= post.id %>" data-toggle="modal"><%= t('delete') %></a>

the modal

<div class="modal hide" id="myModal-<%= post.id %>" tabindex="-1" role="dialog" aria-labelledby="myModalLabel" aria-hidden="true">
    <div class="modal-header">
        <button type="button" class="close" data-dismiss="modal" aria-hidden="true">×</button>
        <h3 id="myModalLabel"><%= t('delete_this_question') %></h3>
    </div>
    <div class="modal-body">
        <p><%= raw post.text %></p>
    </div>
    <div class="modal-footer">
        <button class="btn" data-dismiss="modal" aria-hidden="true"><%= t('cancel') %></button>
        <%= link_to(t('delete'), { :controller => 'posts', :action => 'destroy', :id => post.id } ,:method => :delete, :class => 'btn btn-primary') %>
    </div>
</div>

But it does not work. Rails receives a GET and shows the post, but it does not destroy it.

Any idea? Thanks

Answer 1

I found the following solution on http://rors.org/demos/custom-confirm-in-rails

You can use this completely unobtrusively without having to have a custom delete link or modal content in your view. So in my view I have the standard Rails link (only adding some classes to use the Bootstrap styles):

link_to 'delete', post, method: :delete, confirm: 'Are you sure?', class: 'btn btn-mini btn-danger'

And the following in /app/assets/javascripts/bootstrap-confirmation.js.coffee

$.rails.allowAction = (link) ->
  return true unless link.attr('data-confirm')
  $.rails.showConfirmDialog(link) # look bellow for implementations
  false # always stops the action since code runs asynchronously

$.rails.confirmed = (link) ->
  link.removeAttr('data-confirm')
  link.trigger('click.rails')

$.rails.showConfirmDialog = (link) ->
  message = link.attr 'data-confirm'
  html = """
         <div class="modal" id="confirmationDialog">
           <div class="modal-header">
             <a class="close" data-dismiss="modal">&times;</a>
             <h3>Request confirmation</h3>
           </div>
           <div class="modal-body">
             <p>#{message}</p>
           </div>
           <div class="modal-footer">
             <a data-dismiss="modal" class="btn">Cancel</a>
             <a data-dismiss="modal" class="btn btn-danger confirm">Confirm</a>
           </div>
         </div>
         """
  $(html).modal()
  $('#confirmationDialog .confirm').on 'click', -> $.rails.confirmed(link)

If you want more post specific details in your modal you can always include them as data- attributes in your delete link (just like data-confirm is used to display the confirmation message.)