Question

I am trying to access a dynamically generated Control from a separate thread.
But I am always getting a “Stack Overflow Exception” with my code.

I am using following code:

Private _workerThread As Threading.Thread

Private Sub Main_Load(sender As Object, e As System.EventArgs) Handles Me.Load
    Dim Label As New Label
    Label.Name = "Label1"
    Label.Location = New System.Drawing.Point(12, 12)
    Label.Text = String.Empty
    Label.AutoSize = True

    Controls.Add(Label)

    _workerThread = New Threading.Thread(AddressOf DoWork)
    _workerThread.Priority = Threading.ThreadPriority.BelowNormal
    _workerThread.Start()
End Sub

Private Sub DoWork()
    SetLabelText("Label1", "text")
End Sub

Delegate Sub SetLabelTextCallback(ByVal LabelName As String, ByVal text As String)
Private Sub SetLabelText(ByVal LabelName As String, ByVal text As String)
    If CType(Me.Controls(LabelName), Label).InvokeRequired Then
        Dim d As New SetLabelTextCallback(AddressOf SetLabelText)
        d.Invoke(LabelName, text)
    Else
        CType(Me.Controls(LabelName), Label).Text = text
    End If
End Sub

Apparently InvokeRequired never gets to False. But I can´t get it why.
Maybe someone can tell me what I´m doing wrong.

Answer 1

You are not calling the method SetLabelTextCallback on the thread of the Label,
thus you will recall again on the same thread and InvokeRequired is never false

Delegate Sub SetLabelTextCallback(ByVal LabelName As String, ByVal text As String) 

Private Sub SetLabelText(ByVal LabelName As String, ByVal text As String) 
    Dim l as Label = CType(Me.Controls(LabelName), Label)
    if l.InvokeRequired then
        Dim d As New SetLabelTextCallback(AddressOf SetLabelText) 
        l.Invoke(d, new Object() {LabelName, text} ) 
    Else 
        l.Text = text 
    End If 
End Sub