Question

I am trying to build following gesture:
Click And Hold Right Mouse Button, Click Left mouse button => fire browser back key

RButton & LButton Up::
    Send {Browser_Back}
return

~RButton::return

The problem is I want to consume the last “right button up” when release the right button after this hotkey was pressed. Effectively I dont want to see the context menu poppong up.

Any Help?

Edit: It would be nice if we can preserve right drag.

Answer 1

I’m assuming you don’t want to block the right button menu at all times.

rbutton & lbutton::Send, {Browser_Back}

rbutton::click r

Otherwise exclude the second line.

Update: Since you have now specified that you use “right-drag”
here is another idea (note: I don’t use right-drag so I can’t confirm anything):

rbutton::
Keywait, rbutton, T0.5
If (ErrorLevel) {
    Click r d
    Keywait, rbutton
    Click r u
} Return

lbutton::
if GetKeyState("rbutton", "P")
    Send, {Browser_Back}
Else {
    Click d
    Keywait, lbutton
    Click u
} Return

You will have to hold rbutton and left click then release rbutton within 0.5seconds, or raise the time.
The basic version simply won’t work as far as I know. This is because using & will make rbutton only fire upon release.

If this still doesn’t work you could try something even more complicated: link
Update: I just thought of another variation:

Lbutton::
if GetKeyState("rbutton", "P")
    Send, {Browser_Back}
Else {
    Click d
    Keywait, lbutton
    Click u
} Return

rbutton up::
If (a_priorhotkey != "Lbutton" or a_timeSincePriorHotkey > 500)
    Click r
Return