Question

I am trying to connect Arduino Uno with skm53 GPS module, however before uploading the sketch with the Arduino software, I verified it and found the following error.

Error: #error NewSoftSerial has been moved into the Arduino core as of version 1.0. Use SoftwareSerial instead.

I have included the libraries TinyGPS and NewSoftSerial in the libraries directory of the Arduino tool, I have searched and found that almost all code are the same as mine.

#include <TinyGPS.h>
#include <NewSoftSerial.h>

unsigned long fix_age;
NewSoftSerial GPS(2,3);
TinyGPS gps;
void gpsdump(TinyGPS &gps);
bool feedgps();
void getGPS();
long lat, lon;
float LAT, LON;

void setup(){
    GPS.begin(9600);
    //Serial.begin(115200);
}

void loop(){
    long lat, lon;
    unsigned long fix_age, time, date, speed, course;
    unsigned long chars;
    unsigned short sentences, failed_checksum;

    // Retrieves +/- latitude/longitude in 100000ths of a degree.
    gps.get_position(&lat, &lon, &fix_age);

    getGPS();
    Serial.print("Latitude : ");
    Serial.print(LAT/100000,7);
    Serial.print(" :: Longitude : ");
    Serial.println(LON/100000,7);
}

void getGPS(){
    bool newdata = false;
    unsigned long start = millis();
    // Every 1 seconds we print an update.
    while (millis() - start < 1000)
    {
        if (feedgps ()){
            newdata = true;
        }
    }
    if (newdata)
    {
        gpsdump(gps);
    }
}

bool feedgps(){
    while (GPS.available())
    {
        if (gps.encode(GPS.read()))
            return true;
    }
    return 0;
}

void gpsdump(TinyGPS &gps)
{
    //byte month, day, hour, minute, second, hundredths;
    gps.get_position(&lat, &lon);
    LAT = lat;
    LON = lon;
    {
        feedgps(); // If we don't feed the GPS during this long
                   //routine, we may drop characters and get 
                   //checksum errors.
    }
}

Answer 1

You might be looking at older examples (pre Arduino 1.0 and pre inclusion of softwwareserial).
Those examples would have worked with Arduino .23 and earlier.
Just change your first four lines of code like this and it will compile ok:

#include <TinyGPS.h>
#include <SoftwareSerial.h>

unsigned long fix_age;
SoftwareSerial GPS(2,3);

Then you can delete the NewSoftLibrary to avoid future problems.

Also a suggestion: having two variables named the same but with different case, is very confusing.
Better to use more descriptive and distinquishing names to quickly identify them. Probably a better choice might be ssGPS for the serial software connection interface and tlibGPS for the tiny GPS library.