Question

I am trying to create a macro for an Excel file which has a column (let’s call this column A) of cells, and each cell contains 4 to 5 project Deliverables & Work Products separated by a comma, as well as identified by a tag “DEL” for Deliverable and “WKP” for Work Products.

I wish to accomplish the following with a Macro:

1. I would like to keep column A as it is.
2. Create a column B for Deliverables, which need to be extracted from cells in Col A
3. Likewise, create a column C for Work Products, which need to be extracted from cells in Col A

Let me give an example:

Supposing Cell A1 contains

DEL1: DEL 1 Project Process, DEL2: DEL 2 Project Schedule, WKP1: WKP 1 Work Product Document

Here’s what I want Cell B1 to look like:

DEL1: DEL 1 Project Process, DEL2: DEL 2 Project Schedule

And Cell C1 to look like this:

WKP1: WKP1 Work Product Document

And mind you, not all the cells in Col A will be the exact character length as Cell A1. But they will contain both DELs and WKPs.

Given that the names of the Deliverables and Work Products vary in length, I cannot simply copy Col A and run TextToColumn in order to split it.

So far, the approach I have come up with is to copy Col A to Col B, retain the Deliverables and try to remove Work Products.

As you can see, this entails deleting the part of the string that starts with the comma (“,”) and space (” “) in front of “WKP” and ends with the last character of the Work Product in question (which in this case would be the last character of the entire string itself since it seems that the WKPs are mentioned right after DELs).

While I am able to write a Macro the can find the text “WKP” within each cell range and delete it, I am not able to delete the stuff that comes right after it. In other words, I am only able to produce this for Cell B1:

DEL1: DEL 1 Project Process, DEL2: DEL 2 Project Schedule, 1: 1 Work Product Document

Can someone help me write the Macro to do this? I would appreciate it if the syntax was also explained.

Thanks!

Answer 1

This should do the job. Call it using =WKP_DEL(A1,"DEL") in B1 and =WKP_DEL(A1,"WKP") in C1.

Function WKP_DEL(str As String, DelOrWkp As String) As String

Dim V() As String
Dim SubStr As Variant
Dim WKPs As String
Dim DELs As String
    WKP_DEL = ""
    ' Split the string into an array
    V = Split(str, ",")
    ' Loop through the array adding WKPs to the WKPs string and DELs to the DELs string
    For Each SubStr In V
        If InStr(SubStr, "WKP") > 0 Then
            WKPs = WKPs & Trim(SubStr) & ", "
        End If
        If InStr(SubStr, "DEL") > 0 Then
            DELs = DELs & Trim(SubStr) & ", "
        End If
    Next
    ' Remove the trailing ", " and return the required string
    If DelOrWkp = "DEL" Then WKP_DEL = Left(DELs, Len(DELs) - 2)
    If DelOrWkp = "WKP" Then WKP_DEL = Left(WKPs, Len(WKPs) - 2)
End Function