Home/ Questions/Q 8750353
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-06-13T12:51:04+00:00

I am trying to create a simple .bat file that will generate a .html

  • 0

I am trying to create a simple .bat file that will generate a .html file that contains image links to all the images in the current directory.

Usage:
C:> gallery

Output:
gallery.html

File contents:

<HTML><HEAD></HEAD><BODY>
<IMG SRC="C:/path/path/path/image1.gif">
<IMG SRC="C:/path/path/path/randomepic.gif">
<IMG SRC="C:/path/path/path/asdfsadfasd.gif">
</BODY></HTML>

Note the image files will have unpredictable names, but will always be .gif.

What I’ve got: (in gallery.bat)

 @echo off
    set file_start=<HTML><HEAD></HEAD><BODY>
    set image_start=<IMG SRC="
    set image_dir=`cd`
    set image_end=">
    set file_end=</BODY></HTML>
    set file_name=gallery.html

    echo %file_start% > %file_name%
    for %%image in (*.gif) do @echo %image_start%%image_dir%%%image%image_end% >> $file_name%
    echo %file_end% >> %file_name%

But it doesn’t work. I can’t get the less-than symbol to appear, because the batch file thinks it is an input redirect. If I quote the lines with the < symbol, then the quotes appear in the echo statements.

Also, I can’t get the cd command output to save to the variable %image_dir%

Lastly, the echo statement in the for-loop isn’t printing out correctly. This might be a symptom of the previous problems though.

I’m hoping its just minor syntax problems I am having. Does anyone know how to fix this? Thanks for your time!

Patrick Q

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    FOR variables must be a single character. You cannot use something like %%image.

    You have problems with < and > twice over. Once when you define your variables, and again when you echo the expanded variable. Those characters must either be quoted or escaped with ^.

    You can use quotes during the assignment without including quotes in the variable –
    set "var=value". The assignment of image_end is a bit tricky because of the embedded quote.

    You can avoid the problem with ECHO by escaping the problem characters in your original assignment.

    You cannot use CD to get the current directory. The proper syntax is %CD%. But you don’t need your image_dir variable. You can use the ~f modifier to get the full path of the file name. Type help for from a command prompt for more information about FOR variable modifiers.

    It is more efficient to enclose all the commands that produce output in parentheses and redirect to your output file just once.

    @echo off
setlocal
set "file_start=^<HTML^>^<HEAD^>^</HEAD^>^<BODY^>"
set "image_start=^<IMG SRC=""
set ^"image_end="^>"
set "file_end=^</BODY^>^</HTML^>"
set "file_name=gallery.html"

>"%file_name%" (
  echo %file_start%
  for %%I in (*.gif) do echo %image_start%%%~fI%image_end%
  echo %file_end%
)

    Another way to avoid problems while ECHOing unquoted characters is to use delayed expansion. But ! is valid in file names, and delayed expansion will corrupt expansion of FOR variables if they contain the ! character. So delayed expansion must be toggled on and off within the loop.

    @echo off
setlocal enableDelayedExpansion
set "file_start=<HTML><HEAD></HEAD><BODY>"
set "image_start=<IMG SRC=""
set ^"image_end=">"
set "file_end=</BODY></HTML>"
set "file_name=gallery.html"

>"%file_name%" (
  echo !file_start!
  setlocal disableDelayedExpansion
  for %%I in (*.gif) do (
    set "image=%%~fI"
    setlocal enableDelayedExpansion
    echo !image_start!!image!!image_end!
    endlocal
  )
  endlocal
  echo !file_end!
)
    • 0