Question

I am trying to make a “Achtung! die kurve” – like game in Actionscript 3.0.

So far I’ve done the movement of one of the ‘worms’, and it works alright.

I wanna divide it into different class files, but I can’t seem to get it to work.
I have a .fla file and 4 .as files. So far I only have code in two of these. When I put all my code directly into the fla file, it works perfectly fine, but when I put it into my player class, it won’t ‘add the child’ to the stage.

Here is my player .as file: http://pastebin.com/hZSxT9cu

the reason why I commented the addChild, is because I wanna do this in my mainFile.as

this is from the main file: http://pastebin.com/TAwUYrTU
I’m not quite sure how to call it in the main file, so I’m guessing that this would be the issue.

All the files are named and placed correctly in the same folder, and flash says that each of my .as files are targeting the .fla file, so this doesn’t seem to be the issue.

Any help is much appreciated.

furthermore, if anyone knows how I can change the speed of my sprite, that would be awesome! Can’t seem to get this to work either.

Best regards
Jesper

Answer 1

Looking at the game you reference, it’s obvious that you’re going to need some collision detection. This tutorial on pixel-level collision detection might be useful to get you started.

With your current setup, the only way I can see to increase the speed of the drawing would be to increase the frame rate in your fla.

You can’t add the player instance(s) as a child in your main class because currently it does not have access to it. Actually, it’s very inefficient to create multiple sprites within your player class. A more efficient approach would be to draw your rectangles directly within the graphics instance of your player instance.

I think the following might be a good starting point for what you’re trying to do. Again, I’ve included some comments which I hope will explain what I’m doing.

Set this as the document class in your fla:

package  {

    import flash.display.MovieClip;
    import flash.events.KeyboardEvent;
    import flash.ui.Keyboard;

    public class MainTrink extends MovieClip {

        // define a list of players, their color, and controls
        // this should make it easier to vary the number of players
        private var players:Array = [
            {color: 0xff0000, left: Keyboard.A, right: Keyboard.S},
            {color: 0x0000ff, left: Keyboard.O, right: Keyboard.P},
            {color: 0x00ff00, left: Keyboard.NUMBER_1, right: Keyboard.NUMBER_2},
            {color: 0xffff00, left: Keyboard.LEFT, right: Keyboard.RIGHT},
        ];

        public function MainTrink() {

            var playerData:Object;
            var player:PlayerTrink;

            // Create a player instance for each player specified in the players array
            for (var i:int = 0; i < players.length; i ++) 
            {
                playerData = players[i];

                player = new PlayerTrink();
                player.color = playerData.color;
                player.init();

                this.addChild(player);

                // Add a reference to the instance back onto the players
                // list so that we can access it easily in other methods
                playerData.player = player;
            }

            // add listeners for keyboard events
            this.stage.addEventListener(KeyboardEvent.KEY_DOWN, _onKeyDown);
            this.stage.addEventListener(KeyboardEvent.KEY_UP, _onKeyUp);
        }

        private function _onKeyDown(event:KeyboardEvent):void
        {
            var playerData:Object;
            var player:PlayerTrink;

            // Check whether pressed key is a control for one of our players
            for (var i:int = 0; i < players.length; i ++)
            {
                playerData = players[i];
                player = PlayerTrink(playerData.player);

                if (event.keyCode == playerData.left)
                    player.leftKeyDown = true;

                if (event.keyCode == playerData.right)
                    player.rightKeyDown = true;
            }
        }

        private function _onKeyUp(event:KeyboardEvent):void
        {
            var playerData:Object;
            var player:PlayerTrink;

            for (var i:int = 0; i < players.length; i ++)
            {
                playerData = players[i];
                player = PlayerTrink(playerData.player);

                if (event.keyCode == playerData.left)
                    player.leftKeyDown = false;

                if (event.keyCode == playerData.right)
                    player.rightKeyDown = false;
            }
        }
    }

}

And include this file in the same directory as the fla:

    package  {

    // Need to import other classes referenced within this class
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.events.KeyboardEvent;
    import flash.events.Event;
    import flash.ui.Keyboard;

    // By convention classes are usually named using CamelCase
    public class PlayerTrink extends MovieClip {

        // Move your properties out of your class constructor
        private const TURNSPEED:Number = 0.1;

        private var posX:Number = 50;
        private var posY:Number = 50; 
        private var dirX:Number = 1;
        private var dirY:Number = 1;
        private var dir:Number = 0;

        private var _leftKeyDown:Boolean = false;
        private var _rightKeyDown:Boolean = false;

        private var _color:Number;

        public function PlayerTrink() {
            // constructor code
        }

        public function init():void
        {
            this.addEventListener(Event.ENTER_FRAME, _onEnterFrame);
        }

        private function _onEnterFrame(e:Event):void {
            if(_leftKeyDown) dir -= TURNSPEED;
            if(_rightKeyDown) dir += TURNSPEED;
            dirX = Math.cos(dir);
            dirY = Math.sin(dir);
            posX += dirX;
            posY += dirY;
            drawRect(posX, posY); 
        }

        private function drawRect(x:Number, y:Number):void {
            this.graphics.beginFill(_color);
            this.graphics.drawRect(x, y, 4, 4);
            this.graphics.endFill();
        }                           

        public function set leftKeyDown(value:Boolean):void 
        {
            _leftKeyDown = value;
        }

        public function set rightKeyDown(value:Boolean):void 
        {
            _rightKeyDown = value;
        }                   

        public function set color(value:Number):void 
        {
            _color = value;
        }        
    }   
}