Question

I am trying to make a Arduino program where it receives signals from the Serial monitor and then lights LED’s accordingly, i have it set up with RGB. But I have a problem where all three LED’s light like the blue one only should. here is my code:

#define SENSOR 0   
#define R_LED 11
#define G_LED 10
#define B_LED 9
#define BUTTON 12
int val = 0;
int times = 0;
int btn = LOW;
int old_btn = LOW;
int state = 0;
int r = 0;
int g = 0;
int b = 0;
byte inByte = 0;
char buffer[5];
void setup() {
  Serial.begin(9600);
  pinMode(BUTTON, INPUT);
}
void loop() {
  val = analogRead(SENSOR);
  Serial.println(val);
  if (Serial.available() > 0) {
    inByte = Serial.read();
    if (inByte == '#') {
      r = Serial.read() + 1;
      r = r * 25;
      g = Serial.read() + 1;
      g = g * 25;
      b = Serial.read() + 1;
      b = b * 25;
    }
  }   
  btn = digitalRead(BUTTON);
  if ((btn == HIGH) && (old_btn == LOW)){
    state = 1 - state;
  }
  old_btn = btn;
  if (state == 1){
    analogWrite(R_LED, r);
    analogWrite(G_LED, g);
    analogWrite(B_LED, b);
  }else{
    analogWrite(R_LED, 0);
    analogWrite(G_LED, 0);
    analogWrite(B_LED, 0);
  }
  delay(100);
}

Note: I am sure it is a coding issue, not a mechanical one,for your information.

Answer 1

If I understand what you’re doing correctly, some code such as #987 will be sent on the serial monitor every time you want the color to change, correct? In that case, the issue is that when you do r = Serial.read() + 1; (and the same goes for b and g), Serial.read() is returning the ASCII code for a character from '0' through '9' (48 – 57). Try this:

  r = Serial.read() - '0' + 1;
  r = r * 25;
  g = Serial.read() - '0' + 1;
  g = g * 25;
  b = Serial.read() - '0' + 1;
  b = b * 25;

This will subtract the ASCII code for '0' first, so the numbers will be in the proper 0-9 range.