Question

I am trying to make code in Applescript that makes a new contact with already filled in information. Here is my code:

set contactFirstName to "Brandon"
set contactLastName to "Damante"
set contactStreet to "7688 Somerly Ct"
set contactCity to "New Albany"
set contactCountry to "USA"
set contactZip to "43054"
set contactEmail to "[e-mail]"
set contactNote to "I'm Awesome"
set contactState to "Ohio"
--Address Book Tell Block
tell application "Address Book"
    --Create the Contact
    set theContact to make new name with properties {first name:contactFirstName, last     name:contactLastName, street:contactStreet, city:contactCity, state:contactState,     country:contactCountry, zip:contactZip, email:contactEmail, note:contactNote}
end tell

it highlights the bolded part and says, “Can’t make application ‘Address Book’ into type location reference,” and I’ve never seen that error message before. What does that mean to my code? How can i correct it?

Answer 1

Try this:

set contactFirstName to "Brandon"
set contactLastName to "Damante"
set contactStreet to "7688 Somerly Ct"
set contactCity to "New Albany"
set contactCountry to "USA"
set contactZip to "43054"
set contactEmail to "[e-mail]"
set contactNote to "I'm Awesome"
set contactState to "Ohio"
--Address Book Tell Block
tell application "Address Book"
    set theContact to make new person at end of people with properties {first name:contactFirstName, last name:contactLastName, note:contactNote}
    tell theContact
        make new address at end of addresses with properties {street:contactStreet, city:contactCity, state:contactState, country:contactCountry, zip:contactZip, label:"Work"}
        make new email at end of emails with properties {label:"Work", value:contactEmail}
    end tell
    save
end tell