Question

I am trying to render some data from a large XML using XSLT. The XML data is actually kind of graph data and not hierarchical. and elements are related to each other and as such may end up havin a circular reference (the relation types are different however).

I am trying to traverse through the relationships from one element and visiting each related element and so on. In this way, at times I reach one element that I have already traversed. In such a case, I should stop traversing further as otherwise I shall be running in a cycle.

My problem is that I am not able to store the list of elements that I have already traversed and make a look up everytime I start traversing an element, so that I can stop traversing if the element is in the lookup.

Simply said, I wanted to keep the elements in a lookup table and add each element to it as I traverse.

Is there some solution for this?

Answer 1

A recursive template can pass itself parameters that hold a node set of “previously” processed nodes and a queue of nodes to be processed. This is a functional programming equivalent of modifying state variables.

Sample input:

<graph startNode="a">
    <graphNode id="a">
        <edge target="b" />
        <edge target="c" />
    </graphNode>
    <graphNode id="b">
        <edge target="c" />
    </graphNode>
    <graphNode id="c">
        <edge target="d" />
    </graphNode>
    <graphNode id="d">
        <edge target="a" />
        <edge target="b" />
    </graphNode>
</graph>

XSL 2.0 stylesheet:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="2.0">

    <xsl:output method="xml" indent="yes"/>

    <xsl:key name="graphNodeByID" match="graphNode" use="@id" />

    <xsl:template match="/graph">
        <results>
            <xsl:apply-templates select="key('graphNodeByID', @startNode)"
                     mode="process"/>            
        </results>
    </xsl:template>

    <xsl:template match="graphNode" mode="process">
        <xsl:param name="already-processed" select="/.." />
        <xsl:param name="queue" select="/.." />

        <!-- do stuff with context node ... -->
        <processing node="{@id}" />

        <!-- Add connected nodes to queue, excluding those already processed. -->
        <xsl:variable name="new-queue"
              select="($queue | key('graphNodeByID', edge/@target))
                        except ($already-processed | .)" />

        <!-- recur on next node in queue. -->
        <xsl:apply-templates select="$new-queue[1]" mode="process">
            <xsl:with-param name="already-processed"
                            select="$already-processed | ." />
            <xsl:with-param name="queue" select="$new-queue" />
        </xsl:apply-templates>
    </xsl:template>

</xsl:stylesheet>

Output (tested):

<results>
   <processing node="a"/>
   <processing node="b"/>
   <processing node="c"/>
   <processing node="d"/>
</results>

As specified, no node is processed twice, even though the graph contains cycles.