Question

I am trying to retrieve First Unique set of 2 attributes.

I am looking for each student name with his first unique group. If for a student first group is already taken for any student, next unique group should be listed. I have posted my XML and expected result XML.

I need XSLT statements to get this result (Version 1.0). Thanks.

Here’s my xml structure

<Socrates>
<Student name='Aristotle' group='1' />
<Student name='Aristotle' group='2' />
<Student name='Aristotle' group='3' />
<Student name='Aristotle' group='4' />

<Student name='Plato' group='1' />
<Student name='Plato' group='2' />
<Student name='Plato' group='3' />

<Student name='Xenophon' group='4' />
<Student name='Xenophon' group='5' />
<Student name='Xenophon' group='6' />

<Student name='Critias' group='1' />
<Student name='Critias' group='2' />
<Student name='Critias' group='3' />    
<Student name='Critias' group='4' />
<Student name='Critias' group='5' />
<Student name='Critias' group='6' />
   </Socrates>

Result XML

<Socrates>
    <Student name='Aristotle' group='1' />
<Student name='Plato' group='2' />
<Student name='Xenophon' group='4' />
<Student name='Critias' group='3' />
</Socrates>

Answer 1

Another slightly different approach (although not necessarily a better approach) is to pass a parameter to each student match which contains a comma-delimited of group attributes that have already been output. Every time you match a student, you check whether their group is in his parameter, and if not output the student, and get the next one, appending the current group to the parameter.

Here is the XSLT, which I have commented to try and explain things better

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output indent="yes"/>

   <xsl:template match="Socrates">
      <Socrates>
         <xsl:apply-templates select="Student[1]"/>
      </Socrates>
   </xsl:template>

   <xsl:template match="Student">
      <!-- Parameter containin comma-delimited list of currently output groups -->
      <xsl:param name="groupList" select="','" />
      <xsl:choose>
         <!-- Has the group already been output? -->
         <xsl:when test="contains($groupList, concat(',', @group, ','))">
            <!-- If so, move on to next student record -->
            <xsl:apply-templates select="following-sibling::Student[1]">
               <xsl:with-param name="groupList" select="$groupList" />
            </xsl:apply-templates>
         </xsl:when>
         <!-- Group has not already been output -->
         <xsl:otherwise>
            <!-- Output the record -->
            <xsl:copy-of select="." />

            <!-- Get the next student with a different name -->
            <xsl:apply-templates select="following-sibling::Student[@name!=current()/@name][1]">
               <xsl:with-param name="groupList" select="concat($groupList, @group, ',')" />
            </xsl:apply-templates>
         </xsl:otherwise>
      </xsl:choose>
   </xsl:template>
</xsl:stylesheet>

When applied to your sample XML, the following is output

<Socrates>
   <Student name="Aristotle" group="1" />
   <Student name="Plato" group="2" />
   <Student name="Xenophon" group="4" />
   <Student name="Critias" group="3" />
</Socrates>

Note that this does assume the student elements are always ordered by name in the input XML.