Question

I am trying to send some files from a folder to a fixed email address, the files need to be sent in individual emails, the file names are random.

This topic got me started:

Send individual emails to predefined set of people with all files in a folder

I altered the code a tiny bit to suit my needs, but when I run the macro it isn’t sending the files. I’m sure its a simple mistake but my knowledge is limited!

This is my code:

Option Explicit

Const SOURCE_FOLDER As String = "C:\Users\Me\Desktop\Test"
Const RECIP_A As String = "[e-mail]"
Const EMAIL_BODY As String = "Please find attached file. Thanks and Regards, ABC"

Sub SendPDFs()
    On Error GoTo ErrorHandler

    Dim fileName As String
    fileName = Dir(SOURCE_FOLDER)

    Do While Len(fileName) > 0
        Call CreateEmail(SOURCE_FOLDER & fileName)
        fileName = Dir
    Loop

ProgramExit:
    Exit Sub
ErrorHandler:
    MsgBox Err.Number & " - " & Err.Description
    Resume ProgramExit
End Sub

Function CreateEmail(fileName As String)
    Dim olApp As Outlook.Application
    Dim msg As Outlook.MailItem

    ' create email
    Set olApp = Outlook.Application
    Set msg = olApp.CreateItem(olMailItem)

    ' set properties
     With msg
        .Body = EMAIL_BODY
        .Recipients.Add (RECIP_A)

        .Attachments.Add fileName
        .Send
    End With
End Function

Answer 1

Ah! The only problem with the code is

Const SOURCE_FOLDER As String = “C:\Users\Me\Desktop\Test”

Change that to

Const SOURCE_FOLDER As String = "C:\Users\Me\Desktop\Test\"

Now try it. I tried and tested it and it works.

Also ensure that you have added reference to the Outlook object library.