Question

i am trying to simulate a live view using a canon Camera.

I am interacting with the cam using the CanonSDK, i get an image every a short period in order to simulate a video frame by frame. This works fine, i am using java to do the backend and send the images trough BlazeDS to flex.

The problem is not getting the image, the problem is that when i load a new image using something like:

image.source=my_new_image;

the new image is loaded but it produces a short white blink and it ruins the video…

So i would like to know if the is a way to update an image on flex avoiding the blinking problem, or if i could make a video streaming from java and pick it up with flex…

Thanks in advance!!!

Answer 1

The easy way is to use a technique called double buffering, using two Loaders – one for the image which is visible, and one for the image which is being loaded and is invisible. When the image has completed loading it becomes visible, and the other one becomes invisible and the process repeats.

In terms of efficiency, it would be better to at least use a socket connection to the server for transferring the image bytes, preferably in AMF format since it has little overhead. This is all fairly possible in BlazeDS with some scripting.

For better efficiency you may try using a real-time frame or video encoder on the server, however decoding the video on the client will be challenging. For best performance it will be better to use the built-in video decoder and a streaming server such as Flash Media Server.

UPDATE (example script):

This example loads images over HTTP. A more efficient approach would be to use an AMF socket (mentioned above) to transfer the image, then use Loader.loadBytes() to display it.

private var loaderA:Loader;
private var loaderB:Loader;
private var foregroundLoader:Loader;
private var backgroundLoader:Loader;

public function Main()
{       
    loaderA = new Loader();
    loaderB = new Loader();
    foregroundLoader = loaderA;
    backgroundLoader = loaderB;

    loadNext();
}

private function loadNext():void
{
    trace("loading");
    backgroundLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, loaderCompleteHandler);
    backgroundLoader.load(new URLRequest("http://www.phpjunkyard.com/randim/randim.php?type=1"));
}

private function loaderCompleteHandler(event:Event):void
{
    trace("loaded");

    var loaderInfo:LoaderInfo = event.target as LoaderInfo;
    var loader:Loader = loaderInfo.loader;
    loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, loaderCompleteHandler);

    if (contains(foregroundLoader))
        removeChild(foregroundLoader);

    var temp:Loader = foregroundLoader;
    foregroundLoader = backgroundLoader;
    backgroundLoader = temp;

    addChild(foregroundLoader);

    loadNext();
}