Question

I am trying to write a script that does the following job: it goes through all of the emails in the mailbox, finds the ones that have the word “French” in their subject line and then copies all the subject lines of those emails in a text file. Here is what I came up with

tell application "TextEdit"
    make new document
end tell

tell application "Mail"
    tell the mailbox "Inbox" of account "[e-mail]"
        set numm to count of messages
            repeat with kk from 1 to numm
                set wordsub to subject of the message kk
                tell application "TextEdit"
                    if "French" is in wordsub then
                        set paragraph kk of front document to wordsub & return
                    end if
                end tell
            end repeat
    end tell
end tell

Unfortunately, I keep receiving the error

“TextEdit got an error: The index of the event is too large to be valid.”

and I have already spent a couple of hours trying to fix it without much success. Could you please take a look at my code and see what is wrong with it?

Answer 1

Your main problem is that the number of paragraphs in TextEdit and the number of email messages have nothing to do with each other, so if you’re counting on the number of messages then TextEdit will not understand it. For example you may have 50 messages but TextEdit does not have 50 paragraphs so it errors. As such we just use a separate counter for TextEdit.

I made other changes too. I often see errors happen by having one “tell application” block of code inside another… so I separated them. Also notice that the only code inside of any “tell application” block is only what is necessary for that application to handle. This too avoids errors. These are good habits to have when programming.

Therefore give this a try…

set searchWord to "French"
set emailAddress to "[e-mail]"

tell application "Mail"
    set theSubjects to subject of messages of mailbox "INBOX" of account emailAddress
end tell

set paraCounter to 1
repeat with i from 1 to count of theSubjects
    set thisSubject to item i of theSubjects
    if thisSubject contains searchWord then
        tell application "TextEdit"
            set paragraph paraCounter of front document to thisSubject & return
        end tell
        set paraCounter to paraCounter + 1
    end if
end repeat