Question

I am trying to write a sproc with a transaction. Can anybody tell me if there would be any issues with code below, or if it will work as intended?

ALTER procedure [dbo].[DeleteMetricMeter]

(
    @SectionID int,
    @MetricMeterID int,
    @Result bit output
)

as

declare @MetricMeterCount int
declare @err int
declare @rowcount int

set xact_abort on

begin tran

select @MetricMeterCount = count(*) from luMetricMeters
where fkSectionID = @SectionID

select @err = @@error, @rowcount = @@rowcount 

if (@err <> 0) or (@rowcount = 0)
begin
    goto on_error           
end

delete from luMetricMeterList
where pkMetricMeterID = @MetricMeterID

select @err = @@error, @rowcount = @@rowcount 

if (@err <> 0) or (@rowcount = 0)
begin
    goto on_error           
end 

delete from luMetricMeters
where pkMetricMeterID = @MetricMeterID

select @err = @@error, @rowcount = @@rowcount 

if (@err <> 0) or (@rowcount = 0)
begin
    goto on_error           
end

if (@MetricMeterCount = 1)
begin
    delete from luMetricSections
    where pkSectionID = @SectionID

    select @err = @@error, @rowcount = @@rowcount 

    if (@err <> 0) or (@rowcount = 0)
    begin
        goto on_error           
    end
end

commit tran
set @result = 1
return @result

on_error:
    rollback tran
    set @result = 0
    return @result

Answer 1

There are a few issues with the procedure:

• You should not evaluate rowcount unless it really indicates an error. When there is no data deleted there is no need to rollback.

• Your code is not thread safe. The MetricMeterCount query should be changed to this to prevent other threads from performing the delete in between your select & the execution of the delete:

  select @MetricMeterCount = count(*) 
    from luMetricMeters with (xlock, serializable)
   where fkSectionID = @SectionID  
  

I would write the code like this:

ALTER procedure [dbo].[DeleteMetricMeter]

(
    @SectionID int,
    @MetricMeterID int,
    @Result bit output
)

as

DECLARE @MetricMeterCount int
DECLARE @err int
DECLARE @rowcount int

SET xact_abort ON

BEGIN TRAN

DELETE FROM luMetricMeterList 
 WHERE pkMetricMeterID = @MetricMeterID

SELECT @err = @@error

IF (@err <> 0) 
    GOTO on_error           

DELETE FROM luMetricMeters
 WHERE pkMetricMeterID = @MetricMeterID

SELECT @err = @@error

IF (@err <> 0) 
    GOTO on_error           

IF EXISTS (SELECT * 
             FROM luMetricMeters WITH (xlock, serializable) 
            WHERE fkSectionID = @SectionID)
BEGIN
    DELETE FROM luMetricSections 
     WHERE pkSectionID = @SectionID

    SELECT @err = @@error
    IF (@err <> 0) 
        GOTO on_error           
END

COMMIT TRAN

RETURN (0)

on_error:
    ROLLBACK TRAN
    RETURN (-1)
GO

Note: The return values should be 0 for success and a negative number for failure.