Question

I am trying to write a stored procedure in sql server 2008,I need to remove unwanted spaces in the entries of my table.I categorized the entries in my table to 3 types.My store procedure should remove the spaces around single letter,like,

• A G M words to AGM words
• words A G M words to words AGM words
• A G words to AG words

I tried following stored procedure.

CREATE proc At1 @name nvarchar(100)
as
declare @start int
declare @temp1 nvarchar(100)
declare @temp nvarchar(100)
declare @NthPosition int
declare @N int
set @N=LEN(@name)
set @start=1
set @temp1=''
set @temp=''


    set @NthPosition=charindex(' ',@name,@start)
    if(@NthPosition<>0)
    begin
    while (@NthPosition<>0 and @N<>0)
    begin
    set @temp1=SUBSTRING(@name,@start,@NthPosition-1)
    if(@temp<>'')
    begin
        if(len(@temp1)=1)
        begin
            set @temp=(@temp+@temp1)
        end
        else
        begin
            set @temp=(@temp+' '+@temp1)
        end
    end
    else
    begin
        set @temp=@temp1
    end
    set @start=@NthPosition+1
    set @N=@N-@NthPosition
    set @NthPosition=0
    set @NthPosition=CHARINDEX(' ',@name,@start)
    end
    end
    else
    begin 
            select @name
    end
          select @temp
        GO

and i used ,

    exec At1 'apple A G M mango' 

My expected result: apple AGM mango

But my actual result:apple

I am unable to figure out where the error is..Any suggestions in this regard is more helpful.
I tried to use computed column that would clear the space and i was able to find solution only for pattern #3.I am unable to frame a computed column definition suitable for all the 3 patterns….. Please share your thoughts that will be helpful to me

Answer 1

I think this covers all the cases:

CREATE proc At1 @Name nvarchar(100)
as
declare @New nvarchar(100)
declare @SpacePos int
declare @Single bit
select @New = '',@Single = 0
select @Name = LTRIM(@Name)

while LEN(@name) > 0
begin
    set @SpacePos = CHARINDEX(' ',@Name)
    if @SpacePos = 0 --No more spaces in the string
    begin
        select @New = @New + CASE WHEN @Single = 1 and LEN(@Name) > 1 THEN ' ' ELSE '' END + @Name,
        @Name = ''
    end
    else if @SpacePos = 2 --Single character "word"
    begin
        select @New = @New + SUBSTRING(@Name,1,1),
            @Name = SUBSTRING(@Name,3,100),
            @Single = 1
    end
    else --Multi-character word
    begin
        select @New = @New + CASE WHEN @Single = 1 THEN ' ' ELSE '' END + SUBSTRING(@Name,1,@SpacePos),
            @Name = SUBSTRING(@Name,@SpacePos+1,100),
            @Single = 0
    end
end
select @New
go

And the examples:

exec At1 'apple A G M mango' 
exec At1 'A G M words'
exec At1 'words A G M'

Produces:

apple AGM mango
AGM words
words AGM

(As a simplifying assumption, I assumed I was okay to remove any leading spaces from the original string. I also assume there are no double spaces in the string. If neither of those assumptions is accurate, a bit more work is required)