Question

I am using antlr to generate my parser, but I want to override some of the error reporting. At the moment if I give some incorrect syntax, for example a missing token, antlr gives the error “line 1:11 missing TYPE at ‘.'”

However I can’t find in which method this error is outputted. It is not, as I originally thought, in the reportError() method. Does anyone know where the message is generated?

Thanks!

Answer 1

A MissingTokenException does pass through reportError(...). Let’s say you would like to parse assignments using the grammar below:

grammar T;

parse      : assignment EOF;
assignment : Id '=' Number ';';
Number     : '0'..'9'+ ('.' '0'..'9'+)?;
Id         : ('a'..'z' | 'A'..'Z')+;
Space      : ' ' {skip();};

Now simply override the reportError(...) method like this:

grammar T;

@parser::members {
  @Override
  public void reportError(RecognitionException e) {
    System.out.println("CUSTOM ERROR...\n" + e);
  }
}

parse      : assignment EOF;
assignment : Id '=' Number ';';
Number     : '0'..'9'+ ('.' '0'..'9'+)?;
Id         : ('a'..'z' | 'A'..'Z')+;
Space      : ' ' {skip();};

and then try to parse, say, "= 123;" (a missing Id):

java -cp antlr-3.3.jar org.antlr.Tool T.g
javac -cp antlr-3.3.jar *.java
java -cp .:antlr-3.3.jar Main "= 123;"

CUSTOM ERROR...
MissingTokenException(inserted [@-1,0:0='<missing Id>',<4>,1:0] at =)

As you can see, the custom error message is being printed to the console.

EDIT

And a warning like “no viable alternative …” is a problem in the lexer, not the parser. This happens when the lexer encounters a character that you did not account for in your grammar (or not as a proper token, at least).

Let’s say you parse the input a = 123: (note the : at the end instead of a ;). The lexer will now produce a “no viable alternative …” warning because I didn’t define any token for that :.

An easy solution to account for such mistakes is to add a “catch-all” rule at the end of your lexer grammar that will match any character that is not matched by any lexer rule before it. Whenever such a “catch-all” rule matches, you simply throw an exception (or do something else, of course!) in the @after{...} block of that rule.

Here’s a demo:

grammar T;

@parser::members {
  @Override
  public void reportError(RecognitionException e) {
    System.out.println("CUSTOM ERROR...\n" + e);
  }
}

parse      : assignment EOF;
assignment : Id '=' Number ';';
Number     : '0'..'9'+ ('.' '0'..'9'+)?;
Id         : ('a'..'z' | 'A'..'Z')+;
Space      : ' ' {skip();};

FallThrough
@after{
  throw new RuntimeException(String.format(
      "Encountered an illegal char on line \%d, column \%d: '\%s'", 
      getLine(), getCharPositionInLine(), getText()
    )
  );
}
  :  . // match any char not matched by Number, Id or Space
  ;

If you now parse a = 123:, you will see the following on your console:

Exception in thread "main" java.lang.RuntimeException: 
    Encountered an illegal char on line 1, column 8: ':'
    ...