Question

I am using Delphi7 with the KOL Components and JPegObj.
How can I transfer a PBitmap to PJpeg?

var 
 MyBitmap : PBitMap;
 MyJpeg   : PJpeg;
begin
 MyBitMap := ....;
 MyJPeg.Bitmap.Assign (MyBitMap); // ===> Wrong?
 MyJPeg.SaveToFile ('C:\test.jpg');
end;

Thanks for your help.

EDIT: Picture here:

EDIT: My Code:

program Project2;

{$APPTYPE CONSOLE}

uses
 Kol,
 JpegObj;

var
 Jpeg: PJpeg;
 Bitmap: PBitmap;

begin
 Bitmap := NewBitmap(50, 50);
 try
  Bitmap.Canvas.Brush.Color := $0000FF80;
  Bitmap.Canvas.Ellipse(0, 0, 50, 50);
  Jpeg := NewJpeg;
  try
   Jpeg.Bitmap := Bitmap;
   Jpeg.SaveToFile('test.jpg');
  finally
   Jpeg.Free;
  end;
 finally
 Bitmap.Free;
end;

Runtime Error 216 at 0041128E

EDIT:
I uncommented the line in JpegObj:

 {$DEFINE VER62} // if you plan to use .obj-files from Delphi7 distributive only!

Now the program is just frozen.

EDIT: The program freezes here in JpegObj

function __ftol: Integer;
 var
  f: double;
begin
 asm
  lea    eax, f             //  BC++ passes floats on the FPU stack
  fstp  qword ptr [eax]     //  Delphi passes floats on the CPU stack
 end;
 Result := Integer(Trunc(f));
end;

Answer 1

Disclaimer: The following has been tested on Delphi 2009!

You cannot use PJpeg.Bitmap.Assign on your PJpeg instance because the PJpeg.Bitmap is nil at the time you are accessing it since it’s not instantiated in PJpeg constructor nor later while you were working with that instance. So the attempt to work with the PJpeg.Bitmap leads to an access violation.

Try to assign the bitmap this way (it’s based on the example from the JpegObj extension):

var 
  MyJpeg: PJpeg;
  MyBitmap: PBitmap;
begin
  // the MyBitMap has a picture assigned here
  MyJpeg := NewJpeg;
  try
    MyJpeg.Bitmap := MyBitmap;
    MyJpeg.SaveToFile('c:\test.jpg');
  finally
    MyJpeg.Free;
  end;
end;

Here is a VCL minimalistic demo:

uses
  KOL, JPEGObj;

procedure TForm1.Button1Click(Sender: TObject);
var
  Jpeg: PJpeg;
  Bitmap: PBitmap;
begin
  Bitmap := NewBitmap(50, 50);
  try
    Bitmap.Canvas.Brush.Color := $0000FF80;
    Bitmap.Canvas.Ellipse(0, 0, 50, 50);
    Jpeg := NewJpeg;
    try
      Jpeg.Bitmap := Bitmap;
      Jpeg.SaveToFile('c:\image.jpg');
    finally
      Jpeg.Free;
    end;
  finally
    Bitmap.Free;
  end;
end;

And the amazing result 🙂

Here is another, console minimalistic demo:

program Console;

{$APPTYPE CONSOLE}

uses
  SysUtils, KOL, JPEGObj;

var
  Jpeg: PJpeg;
  Bitmap: PBitmap;    
begin
  try
    Bitmap := NewBitmap(50, 50);
    try
      Bitmap.Canvas.Brush.Color := $0000CCFF;
      Bitmap.Canvas.Ellipse(0, 0, 50, 50);
      Jpeg := NewJpeg;
      try
        Jpeg.Bitmap := Bitmap;
        Jpeg.SaveToFile('c:\image.jpg');
      finally
        Jpeg.Free;
      end;
    finally
      Bitmap.Free;
    end;
  except
    on E:Exception do
      Writeln(E.Classname, ': ', E.Message);
  end;
end.

And the exciting result 🙂