Question

I am using jQuery to loop through an array and comparing each value with a model’s user id. I will only display a specific text if a match is found.

$.each current_user.get('following_ids'), (i, e) =>
  console.log(@model.get('user')._id == e)
  if @model.get('user')._id == e
    @is_following = true
    //break from loop if condition is met
    return false
  else
    @is_following = false
    //else continue looping through
    return true

if @is_following
  $(@el).find('.user_info .follow a').text "following"
else
  $(@el).find('.user_info .follow a').text "follow"

However my code is not working, it always returns me “follow” text. What am I doing wrong here?

Answer 1

Presumably current_user.get('following_ids') is some sort of array of IDs. Two possibilities immediately come to mind:

1. current_user.get('following_ids') doesn’t contain @model.get('user')._id so everything is working as expected.
2. You have a type problem. Perhaps the following_ids is an array of strings and _id is a number or vice versa.

Option 2 needs a little more explanation: CoffeeScript’s == is converted to JavaScript’s === so 1 == '1' is false in CoffeeScript but true in JavaScript. This does make 2 a hidden and possibly surprising variant of 1 but it is special enough to be its own case.

Consider this simplified analogue of your situation:

$.each ['1','2','3'], (i, e) =>
    if 2 == e
        @is_following = true
        return false
    else
        @is_following = false
        return true
console.log @is_following

You’ll get false out of that because 2 == '2' is false is CoffeeScript: http://jsfiddle.net/ambiguous/YsstH/

But, if we fix the types:

$.each [1,2,3], (i, e) =>
    # Only the array changes...
console.log @is_following

Then we get the true result that we’re expecting: http://jsfiddle.net/ambiguous/CxHXu/

---

In any case, since you’re using Backbone, you have Underscore so you could just use _.any:

@is_following = _(current_user.get('following_ids')).any (id) => @model.get('user')._id == id

or better:

want_this_id  = @model.get('user')._id
@is_following = _(current_user.get('following_ids')).any (id) -> want_this_id == id

You’d still have to sort out the type problem though.