Question

I am using the following bunch of softwares:

1. Ant 1.7.1
2. Eclipse Helios
3. Java 1.6
4. Apache thrift 0.8.0

I am using Thrift to generate java source code in Ant using the following code block:

<exec executable="thrift-0.8.0.exe" osfamily="windows">
    <arg value="-out" />
    <arg value="java/src" />
    <arg value="--gen" />
    <arg value="java" />
    <arg file="Sample.thrift" />
</exec>

So, now I want to add the generated src folder automatically to the classpath of the project in Eclipse using Ant so that it is shown as a source folder when I open the project in Eclipse.

NOTE: I understand that the classpath for a project is present in the .classpath file and adding a classpathentry to it would solve my issue. But I want Eclipse to do that instead of me doing it in the .classpath file manually.

Further, I also had a look at the Ant-Eclipse project and found an Ant task to create a new Eclipse Java project and display its src folder as a source folder. But I don’t want a dependency on an external library.

<project name="test" default="eclipse" basedir=".">
    <target name="eclipse">
        <taskdef name="eclipse" classname="prantl.ant.eclipse.EclipseTask" />
        <eclipse>
            <project />
            <classpath>
                <source path="src" />
                <output path="bin" />
            </classpath>
        </eclipse>
    </target>
</project>

Is there a way to do this in the already existing Ant library in Eclipse?

Thanks a lot!

Answer 1

If you really don’t want to depend on anything external then you could consider using an XSLT stylesheet to edit the .classpath file (which is XML).

add-dir.xsl

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:param name="pathToAdd" />

  <xsl:strip-space elements="*" />
  <xsl:output method="xml" indent="yes" />

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="classpath">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
      <!-- don't add a 2nd copy of the classpathentry if one already exists -->
      <xsl:if test="not(classpathentry[@kind = 'src'][@path = $pathToAdd])">
        <classpathentry kind="src" path="{$pathToAdd}" />
      </xsl:if>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

build.xml

<xslt in=".classpath" out=".classpath.edited" style="add-dir.xsl">
  <param name="pathToAdd" expression="java/src" />
</xslt>
<move file=".classpath.edited" tofile=".classpath" overwrite="yes" />