Question

I am using vala.
This is the source code that gives that compile time bug :

private Gee.HashMap<string,VoidFunc> fill_actions()
{
    var actions = new Gee.HashMap<string,VoidFunc>();
    MainWindow win = window;
    actions["t"] = () => _puts(win.title);
    return actions;
}

First I tried to access this.window directly but that gave another error so I tried this with a local scope variable.

Error when doing directly this.window :

This access invalid outside of instance methods

Answer 1

It sounds like VoidFunc is declared with [CCode (has_target = false)]. What that means is that no context information is passed to it, and AFAIK that is the only way delegates work as generic type arguments. The reason for this is limitations in C, so assuming VoidFunc looks like this:

[CCode (has_target = false)]
public delegate void VoidFunc ();

What you’ll get in C is something like this:

typedef void (*VoidFunc)();

As opposed to something like this if you didn’t have the [CCode (has_target = false)]:

typedef void (*VoidFunc)(gpointer user_data);

When you pass around callbacks in C you generally do so with between one and three arguments. Something with all three would look like this:

void foo (VoidFunc void_func, gpointer user_data, GDestroyNotify notify);

The first parameter is the actual function. The second parameter is the value to pass as user_data to the callback, and is what Vala uses to pass context information to the callback (which is what allows it to act as an instance method, or even a closure). The third parameter is used to specify a function to free user_data when it is no longer needed.

What [CCode (has_target = false)] means is that the delegate doesn’t have a user_data argument, and therefore cannot be used as a closure or instance method.

The reason this is necessary with a generic argument is that generics look something like this at the C level:

void foo_bar (gpointer data, GDestroyNotify notify);

The first parameter is the data that you want to use as a generic value, the second is actually only added if the generic argument is owned (as it is in the case of the set methods in Gee), and is called with user_data as an argument when user_data is no longer needed.

As you can see, when trying to use a delegate as a generic, there is nowhere to put the user_data argument, which is why Vala only allows delegates without targets to be generic arguments.

The solution is basically to wrap the delegate in a class:

public delegate void VoidFunc ();

public class YourClass {
  private class VoidFuncData {
    public VoidFunc func;

    public VoidFuncData (owned VoidFunc func) {
      this.func = (owned) func;
    }
  }

  private Gee.HashMap<string,VoidFuncData> fill_actions() {
    var actions = new Gee.HashMap<string,VoidFuncData>();
    string win = "win";
    actions["t"] = new VoidFuncData (() => GLib.debug (win));
    return actions;
  }
}