Question

I am using XSLT for what it is intended for i.e. mapping form 1 xml form to another.

Due to M$ lack of support for 2.0 and all the lovely functionality that comes with (case-less comparisons anyone? I hope someone lost their job for leaving that out of 1.0) plus more I am looking to using AddExtensionObject to add some functions to add the support I require. I believe this to be significantly more secure than allowing scripts to be run.

the annoyance is the plastering of the urn over all my tags. for example.

<INVAC xmlns:myColor="urn:myColor">
<MEMBO>7131</MEMBO>
<FUNDNAME>Fund00b</FUNDNAME>
</INVAC>

when I follow a modified version of http://www.15seconds.com/issue/031112.htm

I want to use the extra functionality but not have the output…….

thanks in advance!

Answer 1

You have found the answer to your main question — the exclude-result-prefixes attribute of xsl:stylesheet should be used to specify all namespace prefixes (a white-space-separated list) that we don’t wished to be copied on literal-result elements.

Your other question is also easy to answer:

case-less comparisons anyone?

Use:

 translate($s1, $vUpper, $vLower) 
=
 translate($s2, $vUpper, $vLower)

This evaluates to true() exactly when the two strings $s1 and $s2 ara case-insensitive-equal.

The variable $vUpper should contain all uppercase letters of the alphabet and the variable $vLower should contain all lowercaseletters of the alphabet.

Here is a complete example:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pNameOfElementsToDelete" select="'DeLetE'"/>

 <xsl:variable name="vUpper" select=
 "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

 <xsl:variable name="vLower" select=
 "'abcdefghijklmnopqrstuvwxyz'"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*[true()]">
  <xsl:if test=
  "not(
   translate(name(), $vUpper, $vLower)
  =
   translate($pNameOfElementsToDelete, $vUpper, $vLower)
   )
 ">
   <xsl:call-template name="identity"/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

when applied on this XML document:

<a>
 <b>
  <Delete/>
 </b>
 <dell/>
 <c>
   <deLete/>
 </c>
</a>

this transformation produces a new XML document in which any element, whose name is equal case-insensitively to "DeLetE":

<a>
   <b/>
   <dell/>
   <c/>
</a>