Question

I am using XSLT to remove unnecessary attributes from some nodes in a file. Nodes which should not be transformed use the following simple template:

<!-- Copy everything else over -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

However, I have found that some nodes are loosing escaped characters contained in their attribute values.

For example, this input:

<field value="Lei Complementar No. 116/2003, Art. 6, &#167; 2&#186;, I."/>

end up looking like this:

<field value="Lei Complementar No. 116/2003, Art. 6, § 2º, I."/>

How can I prevent this unwanted transformation?

Answer 1

I. XSLT 1.0 solution:

Just add this attribute to xsl:output:

encoding="us-ascii"

This causes any non-ascii character to be rendered with its character code.

However, you may still get different outputs, such as:

<field value="Lei Complementar No. 116/2003, Art. 6, &#167; 2&#186;, I."/>

and

<field value="Lei Complementar No. 116/2003, Art. 6, &#xA7; 2&#xBA;, I." />

And, of course, all of these three are just different represenatations of the same string of (unicode) characters.

II. XSLT 2.0 solution:

This uses the <xsl:character-map> instruction and must always produce the same output:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes"
   indent="yes" use-character-maps="chmEscapes"/>

 <xsl:character-map name="chmEscapes">
  <xsl:output-character character="&#167;"
                        string="&amp;#167"/>
  <xsl:output-character character="&#186;"
                        string="&amp;#186"/>
 </xsl:character-map>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

when this transformation is applied on the provided XML document:

<field value="Lei Complementar No. 116/2003, Art. 6, &#167; 2&#186;, I."/>

the wanted, correct result is produced:

<field value="Lei Complementar No. 116/2003, Art. 6, &#167 2&#186, I."/>