Question

I am working on a appliaction in which I have a following schema

Tasks Master

Task_ID
Task_Name

Task_Details

Task_ID
Task_Date
Task_Count (can be any number like 2 or 3 or 4 or 40)

the Input Form is like that which the staff will fill at the end of the day.

Date | Task Name | Task_Count

24/01/2010 | How many cheque books issued today | 12
24/01/2010 | How many ATM Issued today | 7

Now I want a matrix report showing all tasks suppose 28 tasks in vertical row and on given month it should show all the dates of the particular month horizontal direction like from 1 to 31 days or 30 or 28 as per month days with the task_count using PIVOT in query. i am failed to produce the result as i dont know to make it work. please help.

thanks

Answer 1

You’ll need to use a dynamic query since the columns returned by the pivot changes each month.

With some time this could probably be made more elegant, but here’s the basic idea:

declare @StartOfMonth datetime = '11/1/2010';
declare @counter datetime = @StartOfMonth;
declare @sql varchar(MAX) = '';
declare @columnnames varchar(MAX);
declare @columnfilter varchar(MAX);
declare @fieldname varchar(12);

--First, create a string of dynamic columns, one for each day of the month.
WHILE (MONTH(@counter) = MONTH(@StartOfMonth))
BEGIN

    SET @fieldname = '[' + CONVERT(varchar(10), @counter, 101) + ']';

    --Wrap the columns in ISNULL(@,0) to avoid having null values for days without tasks.
    SET @columnnames = ISNULL(@columnnames + ',', '') + 'ISNULL(' + @fieldname + ',0) AS ' + @fieldname;

    --Also create a dynamic list of the Task_Date values to include in the pivot.
    SET @columnfilter = ISNULL(@columnfilter + ',', '') + @fieldname;


    SET @counter = DATEADD(DAY,1,@counter);
END

--Put it all together into a pivot query.
set @sql = 'SELECT Task_Name, ' + @columnnames + ' FROM (';
set @sql = @sql + 'SELECT M.Task_Name, D.Task_Date, D.Task_Count '
set @sql = @sql + 'FROM Task_Detail D JOIN Task_Master M ON D.Task_ID = M.Task_ID) as SourceTable ';
set @sql = @sql + 'PIVOT (SUM(Task_Count) FOR Task_Date IN (' + @columnfilter + ')) AS PivotTable';

exec (@sql)