Question

I am working XSLT where the source looks like this.

Source:

        <Data>
             <AB>all</AB>
             <AB>all2</AB>
             <CD>hhhhhh</CD>
             <DE>hhhshhh</DE>                
        </Data>

Need to write XSLT to get output as

   <Info>
        <XXX>
        <TTT value="all"/>
        <TTT value="all2"/>
        </XXX>
    <!--    ....-->
    <!--    ..to het all the elements..   -->

   </Info>

I have to write xslt to match tag.

    <xsl:template match="AB">


    </xsl:template>

I can do it by matching Data tag.

    <?xml version="1.0" encoding="utf-8"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
        <xsl:output method="xml" indent="yes"/>

         <xsl:template match="Data">
        <info>
          <XXX>
          <xsl:for-each select="AB">
          <TTT>
          <xsl:attribute name="value">
            <xsl:value-of select="."/>
          </xsl:attribute>
          </TTT>
          </xsl:for-each>
          </XXX>
        </info>
          </xsl:template>

    </xsl:stylesheet>

Can any one help me out how to do it by matching AB tag

    <xsl:template match="AB">


    </xsl:template>

Thank you.

Answer 1

I think you are asking how do you use xsl:apply-templates. If so, your XSLT would look like this

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="Data">
      <info>
         <XXX>
            <xsl:apply-templates select="AB"/>
         </XXX>
      </info>
   </xsl:template>

   <xsl:template match="AB">
      <TTT value="{.}"/>
   </xsl:template>
</xsl:stylesheet>

Do also note the use of Attribute Value Templates in the AB template to simplify the XSLT.

If you also require the other non-AB elements to be output unchanged, you would make use of the identity transform in your XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="Data">
      <info>
         <XXX>
            <xsl:apply-templates select="AB"/>
         </XXX>
         <xsl:apply-templates select="node()[not(self::AB)]" />
      </info>
   </xsl:template>
   <xsl:template match="AB">
      <TTT value="{.}"/>
   </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>   
</xsl:stylesheet>

This would also match all non-AB elements, outputing following the XXX element. In your case, it would output the following:

<info>
   <XXX>
      <TTT value="all" />
      <TTT value="all2" />
    </XXX>
    <CD>hhhhhh</CD>
    <DE>hhhshhh</DE>
</info>

Of course, there is no reason you couldn’t have other templates matching elements like CD or DE to transform those too.