Question

I am writing a Perl script which parses an Excel file. The aim of this script is to count for each cell value in column 1, the number of values it has in column 2.

Per example an Excel file that looks like this :

12    abc
12    abc
12    efg
12    efg
13    hij
13    hij
13    klm

My script would return:

For cell value 12 I have :

2 values "abc", 2 values "efg" and for cell value 13 i have : 2 values "hij" and 1 value "klm". 

My script would look something like this (I took this example from the perl doc) :

 use Spreadsheet::XLSX;

 my $excel = Spreadsheet::XLSX -> new ('Book1.xlsx');

 foreach my $sheet (@{$excel -> {Worksheet}}) {

    printf("Sheet: %s\n", $sheet->{Name});

    $sheet -> {MaxRow} ||= $sheet -> {MinRow}; 

     foreach my $row ($sheet -> {MinRow} .. $sheet -> {MaxRow}) {

            $sheet -> {MaxCol} ||= $sheet -> {MinCol};

            foreach my $col ($sheet -> {MinCol} ..  $sheet -> {MaxCol}) {

                    my $cell = $sheet -> {Cells} [$row] [$col];

                    if ($cell) {
                        #here I should count the cell values 
                    }
                print $cell;
            }

    }


 }

I have no idea how to do this since I’ve never used perl before in my life, and I can’t find examples online that match what I want exactly. Any help would be much much appreciated.
Thanks

Answer 1

Perhaps the following commented script will help:

use strict;
use warnings;
use Spreadsheet::XLSX;
use Data::Dumper;

# No need to iterate through columns, so set val for col 1
my $col1 = 0;
my %hash;

my $excel = Spreadsheet::XLSX->new('Book1.xlsx');

# Just get the first sheet
my $sheet = ${ $excel->{Worksheet} }[0];

# Calculate the range of rows
$sheet->{MaxRow} ||= $sheet->{MinRow};

# Iterate through each row
foreach my $row ( $sheet->{MinRow} .. $sheet->{MaxRow} ) {

    # The cell in column 1
    my $cell = $sheet->{Cells}[$row][$col1];

    if ($cell) {

        # The adjacent cell in column 2
        my $adjacentCell = $sheet->{Cells}[$row][ $col1 + 1 ];

        # Use a hash of hashes
        $hash{ $cell->{Val} }{ $adjacentCell->{Val} }++;
    }
}

# Numerically sort the keys; the value is a hash reference
for my $key1 ( sort { $a <=> $b } keys %hash ) {
    print "For cell value $key1: ";

    # Dereference the hash reference and get the keys/values
    while ( my ( $key2, $val2 ) = each %{ $hash{$key1} } ) {
        print qq{$val2 value(s) "$key2" };
    }
    print "\n";
}

# Show the hash structure
print "\n", Dumper \%hash;

Output:

For cell value 12: 2 value(s) "abc" 2 value(s) "efg" 
For cell value 13: 1 value(s) "klm" 2 value(s) "hij" 

$VAR1 = {
          '13' => {
                    'klm' => 1,
                    'hij' => 2
                  },
          '12' => {
                    'abc' => 2,
                    'efg' => 2
                  }
        };

You can do the following to show the values associated with key ’13’:

# Show only the value(s) for key '13'
print "For cell value 13: ";

# Dereference the hash reference for key '13' and get the keys/values
while ( my ( $key2, $val2 ) = each %{ $hash{13} } ) {
    print qq{$val2 value(s) "$key2" };
}

Output:

For cell value 13: 1 value(s) "klm" 2 value(s) "hij"