Question

I am writing an elisp function that permanently binds a given key to a given command in the current major mode’s keymap. For example,

    (define-key python-mode-map [C-f1] 'python-describe-symbol)

The command and the key sequence are gathered interactively from the user. However, I am having trouble producing the name of the KEYMAP (e.g. ‘python-mode-map’) that corresponds to the current major mode.

I have tried the function (current-local-map), but this function returns the keymap object itself, rather than its name.

I understand that many major mode keymaps are named according to the convention ”major-mode-name’-mode-map’, however, this is not always the case (for example, python-shell-map), so I would rather my code not rely on this convention. (I am not even sure how to access the name of the current major mode).

The (define-key ...) is to be added to an init file, so although

(define-key (current-local-map) key command)

seems to work, it does not work as code on an initialization file.

Answer 1

There is no direct way to find the name of the current local keymap—more precisely, the symbol to which its value is bound—because the keymap doesn’t even have to be bound to a symbol. However, mode keymaps typically are bound to a global symbol, and one can find which one it is by iterating through all symbols and stopping on the one whose value is eq to the keymap object.

This has to look at all the symbols (although it does minimum work with each), but has the advantage of not relying on any particular naming convention.

(defun keymap-symbol (keymap)
  "Return the symbol to which KEYMAP is bound, or nil if no such symbol exists."
  (catch 'gotit
    (mapatoms (lambda (sym)
                (and (boundp sym)
                     (eq (symbol-value sym) keymap)
                     (not (eq sym 'keymap))
                     (throw 'gotit sym))))))


;; in *scratch*:
(keymap-symbol (current-local-map))
==> lisp-interaction-mode-map