Question

I am writting a code to disable selcted items in LISTBOX.
i.e I want to show item in list but don’t want user to select it.
As shown in image below. Or similar image in link.
Is it possible in VB6 ?
Please help.

Answer 1

You can’t do this with a ListBox without serious owner-draw fun. However, you could do it with a list view control.

The closest I have done to this is to change the forecolor of disabled list items, and intercepted item click events so that the item is unselected. The Tag property of the list item is used to store the “disabled” state.

I ought to mention that I couldn’t get this code to prevent the item from being “selected” whilst the mouse button is done. To do this, you would have to do some subclassing.

The following class “ListViewWrapper” should be added to the project:

Option Explicit

Private Const m_ksDisabled                  As String = "D"

Private WithEvents m_oListView              As ListView

Public Sub Initialise(ByRef the_oListView As ListView)

    Set m_oListView = the_oListView

End Sub

Public Property Let ListItemEnabled(ByVal the_oListItem As ListItem, ByVal the_bEnabled As Boolean)

    If Not the_oListItem Is Nothing Then
        If the_bEnabled Then
            the_oListItem.Tag = Empty
            the_oListItem.ForeColor = vbWindowText
        Else
            the_oListItem.Tag = m_ksDisabled
            the_oListItem.ForeColor = vbGrayText
        End If
    End If

End Property

Public Property Get ListItemEnabled(ByVal the_oListItem As ListItem) As Boolean

    If Not the_oListItem Is Nothing Then
        ListItemEnabled = (the_oListItem.Tag <> m_ksDisabled)
    End If

End Property

Private Sub m_oListView_ItemClick(ByVal Item As MSComctlLib.ListItem)

    If Item.Tag = m_ksDisabled Then
        Set m_oListView.SelectedItem = Nothing
    End If

End Sub

It should be used like this:

Private m_oListViewWrapper              As ListViewWrapper

Private Sub Form_Load()

    Set m_oListViewWrapper = New ListViewWrapper
    m_oListViewWrapper.Initialise ListView

End Sub

Private Sub Command_Click()

    With m_oListViewWrapper
        .ListItemEnabled(ListView.SelectedItem) = Not .ListItemEnabled(ListView.SelectedItem)
    End With

End Sub