Question

I apologise if this question already exists, I searched for a while but couldn’t find anything.

I have 2 columns in Excel and I need to concatenate the values of 1 column where the values of another are the same. As an example I have this:

A  | B
12 | Value 1
10 | Value 2
13 | Value 3
12 | Value 4
10 | Value 5

And I would like to get out:

A  | B
12 | Value 1, Value 4
10 | Value 2, Value 5
13 | Value 3

I have thousands of rows and ideally I would like it to create a new worksheet with the results and not destroy the existing sheet. There are also some blank values in column B which I would like it to ignore and not concatenate.

Thanks in advance.

Answer 1

Try this:

Sub combineValues()
    Dim dic As Dictionary
    Dim key, val, i, p, k
    Set dic = New Dictionary
    For i = 1 To Worksheets(1).Range("A65536").End(xlUp).Row
        key = Worksheets(1).Cells(i, 1).Value
        val = Worksheets(1).Cells(i, 2).Value
        If dic.Exists(key) Then
            dic.Item(key) = dic.Item(key) & ", " & val
        Else
            dic.Add key, val
        End If
    Next
    p = 1
    For Each k In dic.Keys
        Worksheets(2).Cells(p, 1) = k
        Worksheets(2).Cells(p, 2) = dic.Item(k)
        p = p + 1
    Next
End Sub

Note that you’ll have to include “Microsoft Scripting Runtime” in “Reference” in order to use Dictionary.

Tested with following [Sheet 1]:

1   value 1
2   value 2
3   value 3
1   value 4
1   value 5
3   value 6
3   value 7
2   value 8
1   value 9
2   value 10
2   value 11
2   value 12

Results in following [Sheet 2]:

1   value 1, value 4, value 5, value 9
2   value 2, value 8, value 10, value 11, value 12
3   value 3, value 6, value 7