Question

I basically have a setup like this:

C:\Upload\A
C:\Upload\B
C:\Upload\C
C:\Upload\D
C:\Upload\E

Where A, B, C, D, E are always different (product IDs) and will always be a different amount (it won’t always be 5 sub-directories). Each of these sub-directories contains 24 images numbered numerically 01-24.

I need to create a batch file that looks at the Upload directory, gets the name of each sub-directory and appends that name to beginning of each image file contained within that sub-directory.

So, C:\Upload\A\01.jpg would become C:\Upload\A\A-O1.jpg as well as the other 23 images in each sub-directory.

The batch file needs to do the same for every sub-directory within the Upload directory.

This sounds extremely complicated to me and where I have started to try and write this, I don’t yet have anything worth sharing in this post.

Any help will be appreciated.

Answer 1

This will rename files in the subdirectories of “C:\Upload”

@echo off
for /d %%D in (C:\Upload\*) do (
  for /f "eol=: delims=" %%F in ('dir /b /a-d "%%D" ^| findstr /vbic:"%%~nD-"') do (
    ren "%%D\%%F" "%%~nD-%%F"
  )
)

I put in extra code to prevent renaming the same file twice. You should be able to safely run the script multiple times.

If you want to recurseively rename files in each subdirectory tree, then a slight change is needed to the code.

@echo off
for /d /r "C:\Utils" %%D in (*) do (
  for /f "eol=: delims=" %%F in ('dir /b /a-d "%%D" ^| findstr /vbic:"%%~nD-"') do (
    ren "%%D\%%F" "%%~nD-%%F"
  )
)