Question

I cannot figure out how to send more than 1 workbook for the life of me!
I know a couple different ways to email 1 workbook, I place them here.

Sub SendActiveWorkbook()
                ActiveWorkbook.SendMail _
    Recipients:=Array("[e-mail]", "[e-mail]"), _
    Subject:="Write subject here"                 
End Sub

And

Sub RouteActiveWorkbook()   
    With ActiveWorkbook
           .HasRoutingSlip = True
               With .RoutingSlip
                    .Delivery = xlAllAtOnce
                    .Recipients = Array("[e-mail]", "[e-mail]")
                    .Subject = "CSAM Lux BIEO and BCF breakdown"
                    .Message = "Attached are the breakdowns as of " & Date
               End With
            .Route
     End With
End Sub

I seem to be only able to send 1 workbook in a given email. (it will not solve my problem to make my 2 workbooks into 1 workbook). Anyone had any success with sending more than 1 workbook in an email?

Answer 1

This is a basic example to send an email with more than 1 attachment. Please amend as applicable for realistic scenario. Also I have not taken care of error handling in the below example.

TRIED AND TESTED

Option Explicit

Sub Sample()
    Dim OutApp As Object
    Dim OutMail As Object
    Dim MyFileList(1) As String
    Dim i As Long
    
    '~~> Change/Add the file names here
    MyFileList(0) = "C:\Sample1.xlsm"
    MyFileList(1) = "C:\Sample2.xlsm"
    
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    
    With OutMail
        .To = "[e-mail]"
        .Subject = "Example for attaching 2 files"
        .Body = "Hi Ommit :)"
                
        For i = LBound(MyFileList) To UBound(MyFileList)
            .Attachments.Add MyFileList(i)
        Next i
                
        .Display
    End With
End Sub