Question

I copied this script from here but I’m not sure how to modify it to make it just call the url as a GET request – but I don’t need it to write any file output based on the url’s response.

script.vbs

sSrcUrl = "http://localhost:8080/trigger_url"
sDestFolder = "D:\script\"
sImageFile = "output.txt"
set oHTTP = WScript.CreateObject("MSXML2.ServerXMLHTTP")
oHTTP.open "GET", sSrcUrl, False
oHTTP.send ""
set oStream = createobject("adodb.stream")
Const adTypeBinary = 1
Const adSaveCreateOverWrite = 2
oStream.type = adTypeBinary
oStream.open
oStream.write oHTTP.responseBody
oStream.savetofile sDestFolder & sImageFile, adSaveCreateOverWrite
set oStream = nothing
set oHTTP = nothing

What’s the minimum that this script would need to just ping the url?

Answer 1

If this:

   Dim sSrcUrl : sSrcUrl   = "http://localhost:8080/trigger_url"
   Dim oHTTP   : Set oHTTP = WScript.CreateObject("MSXML2.ServerXMLHTTP")
   oHTTP.open "HEAD", sSrcUrl, False
  On Error Resume Next  
   oHTTP.send ""
   If 0 = Err.Number Then
      WScript.Echo oHTTP.Status, sSrcUrl
   Else
      WScript.Echo Err.Description
   End If  
  On Error GoTo 0  

gives you something like:

200 http://localhost:8080/trigger_url

all you have to read about/learn starting here is “.open”, “.send”, and “.Status”.