Question

I created a custom GridView (actually a RadGrid) which does roughly the following.

1. Initialize GridView formatting
2. Setup Columns (depending on type of data to be displayed)
3. Populate the rows

When Instantiating this GridView, and adding it to my page, I want the first column to contain a “rowspan” attribute on the first row of repeated, but similar data. The “rowspan” value should be equal to the number of similar rows following it. In this way I hope to make the final view cleaner.

The logic for this, I figure, should take place while populating the rows. Initially I add rows to a DataTable and then bind it to the GridView as the final step.

Here’s the general logic I was attempting, but it didn’t work for me. What am I doing wrong?

Dim dt As New DataTable() 'Has three default columns
For Each d In Documents 'MAIN ITEM (First Column Data)
    Dim rowspan As Integer
    rowspan = 0
    For Each f In Files
        If rowspan = 0 Then
            Me.dt.Rows.Add(New Object() {d.Title, f.Language, f.FileSize})
            'THIS DOESN'T WORK!
            Me.dt.Columns(0).ExtendedProperties.Item("rowspan") = rowspan.ToString()
        Else
            Me.dt.Rows.Add(New Object() {Nothing, f.Language, f.FileSize})
        End If
        rowspan += 1
    Next
Next

Also keep in mind that the this is dumped into a DataView which is sorted by the first column, so I would imagine it must actually be sorted first, then somehow count the rows for each “like” first column, then set the “rowspan” value for the first row of that column equal to the number of rows belonging to it.

Does this make sense? Here is an ideal example of what I would like to accomplish in the layout:

Answer 1

Try this.

Protected Sub DemoGrid_PreRender(sender As Object, e As System.EventArgs) Handles DemoGrid.PreRender
    MergeRowsWithSameContent(sender)
End Sub

Public Sub MergeRowsWithSameContent(gvw As GridView)
    For rowIndex As Integer = gvw.Rows.Count - 2 To 0 Step -1
        Dim row As GridViewRow = gvw.Rows(rowIndex)
        Dim previousRow As GridViewRow = gvw.Rows(rowIndex + 1)

        For i As Integer = 0 To row.Cells.Count - 1
            If row.Cells(i).Text = previousRow.Cells(i).Text Then
                row.Cells(i).RowSpan = If(previousRow.Cells(i).RowSpan < 2, 2, previousRow.Cells(i).RowSpan + 1)
                previousRow.Cells(i).Visible = False
            End If
        Next
    Next
End Sub

P.S: Shameless port of this wonderful code I have been using for years.