Question

I developed a small application in Delphi with TEdit components on it.
I used this function to validate if the component fields are not empty.

function TF_config.Validatefields:boolean;
var 
  i : integer;
begin
 for i := 0 to ComponentCount - 1 do
 begin
   if (Components[i]is TEdit) then
   begin
      if ((TEdit(Components[i]).Text) ='') then
      begin
        MessageDlg('Enter data in all the fields',mtWarning,[MBOK],0);
        TEdit(Components[i]).SetFocus;
        result := false;
        exit;
     end;             
   end;  //end for TEdit
 end;    //end component count 
 result := true;
end;

Now I have to add one more component

The order in which the function checks for data if valid is
ID->Name->Address->Phone->Age. But I want it to be ID->Name->Address->Age->Phone.
I tried solving it deleting the Phone Edit component and later add it after adding the Age Edit component.Or using the Phone Edit component for Age and add new Edit component for Phone. This is easier for few components, but becomes tedious when having many of them.
So I was wondering if we could arrange the components in a manner that suits us. Is this possible?

Answer 1

I would suggest putting the controls in your own list/array, then you have full control over its content and ordering, and can loop through it when needed. This also ensures that you touch only the controls you are actually interested in and not wasting time touching other controls that you are not interested in, and it also allows the VCL to maintain its own ordering of its own internal lists as it sees fit.

type
  TF_config = class(TForm)
    procedure FormCreate(Sender: TObject);
  ...
  private
    EditFields: array[0..4] of TEdit;
    function ValidateFields: Boolean; 
  ...
  end;

procedure TF_config.FormCreate(Sender: TObject);
begin
  EditFields[0] := IdEdit;
  EditFields[1] := NameEdit;
  EditFields[2] := AddressEdit;
  EditFields[3] := AgeEdit;
  EditFields[4] := PhoneEdit;
end; 

function TF_config.ValidateFields: Boolean; 
var  
  i : integer; 
begin 
  for i := Low(EditFields) to High(EditFields) do 
  begin 
    if EditFields[i].GetTextLen = 0 then 
    begin 
      MessageDlg('Enter data in all the fields', mtWarning, [MBOK], 0); 
      EditFields[i].SetFocus; 
      Result := False; 
      Exit; 
    end;              
  end;
  Result := True; 
end; 

Update: If you have multiple types of controls that you need to validate, you can do this instead:

type 
  TF_config = class(TForm) 
    procedure FormCreate(Sender: TObject); 
  ... 
  private 
    Fields: array[0..4] of TControl; 
    function ValidateFields: Boolean;  
  ... 
  end; 

procedure TF_config.FormCreate(Sender: TObject); 
begin 
  Fields[0] := ...; 
  Fields[1] := ...; 
  ...
  Fields[4] := ...; 
end;  

function TF_config.ValidateFields: Boolean;  
var   
  i : Integer;  
  ctrl: TControl;
begin  
  Result := True;
  for i := Low(Fields) to High(Fields) do  
  begin  
    ctrl := Fields[i];
    if ctrl is TCustomEdit then // handles both TEdit and TMemo
    begin  
      if TCustomEdit(ctrl).GetTextLen = 0 then  
      begin  
        Result := False;
        Break;
      end;               
    end;
    if ctrl is TComboBox then
    begin  
      if TComboBox(ctrl).ItemIndex = -1 then  
      begin  
        Result := False;
        Break;
      end;               
    end;
    ... and so on ...
  end;
  if not Result then
  begin
    MessageDlg('Enter data in all the fields', mtWarning, [MBOK], 0);  
    ctrl.SetFocus;  
  end;
end;