Question

I don’t know if this question will make sense to begin with…

Example Given: the following value is given for a single cell (we’ll call it A1): Sub-value #1|Here's another sub-value #2|Yet again, last but not least, sub-value #3. I already know someone will tell me that this is where a database should be used (trust me, my major is DB Management, I know, but I need my data in this fashion). My delimiter is the |. Now say I want to create a function that will take the LEN() of each sub-value and return the AVERAGE() of all the sub-values. If I wanted to create a single function to do this, I could use an split(), take each value, do an LEN() and return the AVERAGE().

For the example given, let’s utilize cell B1. I have created similar functions in the past that would work by the following method (although not this exact one), but it requires splitting and joining the array/cell value(s) each time: =ARRAY_AVERAGE(ARRAY_LEN(A1,"|","|"),"|","|").

• ARRAY_LEN(cell,delimiter[,Optional new_delimiter])
• ARRAY_AVERAGE(cell,delimiter[,Optional new_delimiter])

However, I’m wondering if there might be a more dynamic approach to this. Basically, I want to split() an array with some custom VBA function, pass it to parent cell functions, and I wrap up the array by a function that will merge the array back together.

Here’s how the cell function will run:
=ARRAY_AVERAGE(ARRAY_LEN(ARRAY_SPLIT(A1,"|"))).

• ARRAY_SPLIT(cell,delimiter) will split the array.
• ARRAY_LEN(array) will return the length of each sub-value of the array.
• ARRAY_AVERAGE(array) will return the average of each sub-value of the array. Since this function returns a single value of multiple values, this will take the form of an imaginary ARRAY_JOIN(array,delimiter) that would merge the array back again.

This requires one or two additional functions in the cells, but it also lowers the number of iterations that the cell would be converting to and from a single cell value and VBA array.

What do you think? Possible? Feasible? More or less code efficient?

Answer 1

Here are 2 example VBA UDFs that work on a single cell: enter the formula as

=AVERAGE(len_text(SPLIT_TEXT(A1,”|”)))

Note that in this particular case you don’t actually need the len_text function, you could use Excel’s LEN() instead, but then you would have to enter the AVERAGE(..) as an array formula.

Option Explicit

Public Function Split_Text(theText As Variant, Delimiter As Variant) As Variant
    Dim var As Variant
    var = Split(theText, Delimiter)
    Split_Text = Application.WorksheetFunction.Transpose(var)
End Function
Public Function Len_Text(something As Variant) As Variant
    Dim j As Long
    Dim k As Long
    Dim var() As Variant

    If IsObject(something) Then
        something = something.Value2
    End If

    ReDim var(LBound(something) To UBound(something), LBound(something, 2) To UBound(something, 2))
    For j = LBound(something) To UBound(something)
        For k = LBound(something, 2) To UBound(something, 2)
            var(j, k) = Len(something(j, k))
        Next k
    Next j
    Len_Text = var

End Function