Question

I found nothing in Google, so…

I try to use all objected-oriented features of Fortran 90 and create module for some specific work (like class in C++). I have written something like this:

module test

integer, PRIVATE :: dummy
PUBLIC :: sub

contains 

subroutine sub()
dummy = 1
end subroutine sub

end module test

But, I have about 10 such subroutines and it’s very bad idea to place them all into one file. Is it possible to tell compiler, that sub is module subroutine, but place it in another file? Because, it looks like this code will be compiled only if I define body of sub there.

Answer 1

As a direct answer to your question – yes – you can use a INCLUDE line to reference a file that contains the definition of sub from within the file that contains the definition of the rest of the module (the include line for the files with the subroutine code would come after the CONTAINS statement in the module.

MODULE test
  INTEGER, PRIVATE :: dummy
  PUBLIC :: sub
CONTAINS
  INCLUDE 'sub.f90'
END MODULE test

! sub.f90
SUBROUTINE sub
  dummy = 1
END SUBROUTINE sub

However, this is an atypical arrangement. Further, if it is a “very bad idea to place them all into one file”, then is it a good idea (or necessary) to have the presumably disparate subroutines available from the one module?

The more conventional F90 solution is for the shared data (dummy) to be placed in one “low level” module as public entities, to place the subroutine definitions into a series of “intermediate level” modules that use the low level module as required, and then for a final “high level” module that uses the intermediate modules and provide a collective export to client code. Source code conventions, rather than language rules, are then used to avoid client code from directly using the intermediate and low level modules.

MODULE low_level_shared
  IMPLICIT NONE
  INTEGER, PUBLIC :: dummy
END MODULE low_level_shared

MODULE intermediate_sub1
  IMPLICIT NONE
CONTAINS
   SUBROUTINE sub1
     USE low_level_shared
     dummy = 1
   END SUBROUTINE sub1
END MODULE intermediate_sub1

MODULE intermediate_sub2
  IMPLICIT NONE
CONTAINS
   SUBROUTINE sub2
     USE low_level_shared
     ...
   END SUBROUTINE sub2
END MODULE intermediate_sub2

MODULE high_level
  USE intermediate_sub1
  USE intermediate_sub2
  PRIVATE
  PUBLIC :: sub1, sub2
END MODULE high_level

PROGRAM client_code
  USE high_level
  ...
  CALL sub1
END PROGRAM client_code

Fortran 2008 allows additional structures and control through the submodule feature, where module procedures interfaces can be defined in a separate program unit to the module procedure implementation.