Question

I googled a bit but could not find a good solution. I have a sequence of events: A, B and C occurring over time repeatedly and I want to plot this on a timeline somewhat as follows:

AAABBBBAAAAACCAAAAAAAAABBBBABBBBB

But in a more aesthetic and colorful way. I use gnuplot, so, if someone knows the trick with gnuplot, that would be great.

The format of raw data is as follows:

A   4
B   6
C  10
A  14
B  17
C  22
A  27
B  27
C  35
A  35

And the gnuplot script that I worked out is as follows:

set terminal png enhanced
set style data histograms

set style histogram columnstacked
set output "timeline.png"
set xlabel "events"
set ylabel "min"
set auto x
set xtics 1
set key top left
set boxwidth 0.5 relative
set style fill solid 0.6 border -1
plot 'timeline.txt' using 2 t "execution"

After running this script on above data, I get the following plot:

I want: 1) the colors to be repeating based on the letters on first column and 2) the histogram to be horizontal, one-dimension plot.

Thanks for any help.

Answer 1

How about something like this:

sum=0
cum_sum(x)=(sum=sum+x,sum-x/2)
set yrange [-1:2]
set xrange [0:*]
unset ytics
set style fill solid
plot 'test.dat' using (cum_sum($2)):(1.0):($2):($0) w boxes t "execution" lc variable

and here’s a version which colors the boxes based on the label (I have to admit, I’m pretty proud of this hack):

sum=0
cum_sum(x)=(sum=sum+x,sum-x/2)
set yrange [-1:2]
set xrange [0:*]
unset ytics
set style fill solid
LABELS="ABCD"
plot 'test.dat' using (cum_sum($2)):(1.0):($2):(strstrt(LABELS,strcol(1))) w boxes t "execution" lc variable

If you want to control which color a particular label gets, you’d want to use set style line X lc rgb 'cyan' where the label which starts at index X in the LABELS string will be colored cyan.