Question

I got this function to split string but it’s giving the spited string in one column I want like below.

How can i modify the function to get the output like below.

I found this function on google.

CREATE FUNCTION dbo.Split(@String varchar(8000), @Delimiter char(1))       
returns @temptable TABLE (items varchar(8000))       
as       
begin       
    declare @idx int       
    declare @slice varchar(8000)       

    select @idx = 1       
        if len(@String)<1 or @String is null  return       

    while @idx!= 0       
    begin       
        set @idx = charindex(@Delimiter,@String)       
        if @idx!=0       
            set @slice = left(@String,@idx - 1)       
        else       
            set @slice = @String       

        if(len(@slice)>0)  
            insert into @temptable(Items) values(@slice)       

        set @String = right(@String,len(@String) - @idx)       
        if len(@String) = 0 break       
    end   
return       
end  



SELECT * from dbo.Split('hello hi guys',' ');

items
--------
hello
hi
guys

I want like this 

col1    col2     col3
_____  _______  _______
hello   hi       guys

Answer 1

If you can guarantee that no XML characters will be passed into @String, try the following…

UPDATED to make “safer” against XML characters (although it still will fail if ]]> is contained…

CREATE FUNCTION dbo.Split(@String varchar(8000), @Delimiter char(1))       
returns @temptable TABLE (col1 varchar(8000), col2 varchar(8000), col3 varchar(8000))       
as       
begin
    declare @xml xml
    set @xml = '<data><col><![CDATA[' + 
                replace(@String,@Delimiter,']]></col><col><![CDATA[') + 
                ']]></col></data>'

    insert into @temptable (col1, col2, col3)
    select parts.value('col[1]','varchar(8000)'),
        parts.value('col[2]','varchar(8000)'),
        parts.value('col[3]','varchar(8000)')
    from @xml.nodes('/data') as parts(parts)
return       
end