Question

I got this query:

DECLARE @UserId INT
DECLARE @StateChangeInformation XML

SET @UserId = 1
SET @StateChangeInformation = '<stateChangeInformation EnableOverrideMarking="1"></stateChangeInformation>'
SET @command = 'DECLARE @UserIdXml XML; SET @UserIdXml = ''<userID>{ sql:variable("@UserId") }</userID>''; SET @StateChangeInformation.modify(''insert sql:variable("@UserIdXml") into (/stateChangeInformation)[1]'')'

EXEC sp_executesql @stmt = @command,
                   @params = N'@StateChangeInformation xml out',
                   @StateChangeInformation= @StateChangeInformation OUTPUT

SELECT @StateChangeInformation

What I want to do is to output the XML as:

<stateChangeInformation>
  <userID>1</userID>
</stateChangeInformation>

Currently, I am getting the following output:

<stateChangeInformation EnableOverrideMarking="1">
  <userID>"{ sql:variable("@UserId") }"</userID>
</stateChangeInformation>

Please help!

Answer 1

You need to send @UserId as a parameter to the dynamic SQL and use concatenation to get the value in the XML.

DECLARE @command nvarchar(max)
DECLARE @UserId INT
DECLARE @StateChangeInformation XML

SET @UserId = 1
SET @StateChangeInformation = '<stateChangeInformation EnableOverrideMarking="1"></stateChangeInformation>'
SET @command = 'DECLARE @UserIdXml XML; 
                SET @UserIdXml = ''<userID>''+cast(@UserId as varchar(10))+''</userID>''; 
                SET @StateChangeInformation.modify(''insert sql:variable("@UserIdXml") into (/stateChangeInformation)[1]'')'

EXEC sp_executesql @stmt = @command,
                   @params = N'@StateChangeInformation xml out, @UserId int',
                   @StateChangeInformation= @StateChangeInformation OUTPUT, @UserId = @UserId

SELECT @StateChangeInformation