Question

I have 2 arrays

    @a = qw/ A B C D E     /;
    @b = qw/ B B C       A /;    

I need to check if the same element appear in the same position of each array

    e.g. 

    $a[2] = "B";
    $b[3] = "C";

if so count the number of times this happened
it need to disregard any blank elements

    e.g.

    $a[6] =  ;
    $b[6] =  ;

comments are most appreciated I like to understand the script.

I tried intersect eq == cmp etc but I can’t quite get it and not quite sure

Thanks in advance.

Here’s my code so far:

#!/usr/bin/perl -w

my @a = <FILE1>;
my @b = <FILE2>;

$occurs = 0; #Using eq
foreach my $letter (@a) {
    if (my $letter2 (@a) eq $letter) { #Syntax error here
        $count ++;
    }
} #syntax error here

Answer 1

The definition of blank here needs to be clarified. Is it an empty string? An undefined value? Whitespace?

I’m assuming any element with no non-whitespace characters as blank in the example below, which shows how it could be done with the each @array construct:

use strict;
use warnings;

my @a = ( 'A', 'B', 'C', 'D', 'E', ' ', ' ' );  # Can't use qw/ / 'cos
my @b = ( ' ', 'B', 'C', ' ', ' ', ' ', 'A' );  # it ignores whitespace

my %count;                                      # Store results in a hash

while ( my ( $index, $value ) = each @a ) { # Loop over index & value together

    my $otherValue = $b[$index];            # Get the other value in @b

    next unless $value =~ /\S/ and $otherValue =~ /\S/;  # Skip if 'blank'

    $count{$value}++ if $value eq $otherValue; # Increment counter for that value
}

print "$_ : $count{$_}\n" for keys %count;     # B : 1
                                               # C : 1

# Find out total

use List::Util 'sum';                          # No need to reinvent wheel
print "Sum : ", sum ( values %count ), "\n";   # Sum : 2