Question

I have 2 Excel 2007 Worksheets.

Excel Worksheet 1 : (as below ) 3 Columns are important in Sheet 1

userid   name   email

100      sam    [e-mail]
200      pete   [e-mail]
300      Bum    [e-mail] 
400      Harry  [e-mail]

Worksheet 2 : (as below) ( user_id column is empty for all )

userid   name   email

         sam    [e-mail]
         Harry  [e-mail] 
         pete   [e-mail]
         Bum    [e-mail] 

I need a function/forumla with a macro where i can fill the values for userid in sheet 2
where the sheet2 email = sheet1 email

which will result as following in worksheet 2

userid   name   email

100      sam    [e-mail]
400      Harry  [e-mail] 
200      pete   [e-mail]
300      Bum    [e-mail] 

I know SQL but the query takes a long long time on MySQL DB to get the result…
Anyways below is the SQL query i was using in the DB.

UPDATE  `j_A` 
SET user_id =   ( SELECT j_B.id
FROM j_B
WHERE j_B.email =  j_A.email)
WHERE EXISTS
  ( SELECT j_B.id
    FROM j_B
    WHERE j_B.email =  j_A.email);

Need Macro/Function/formula to Replace the Values of one Excel Sheet if both Email(Column) value matches,, if anyone cud help me regarding this creating Macro/Formula/functin etc…since
dont have much knowldge of creating formulae in Excel Macros..

Thanks in advance.

Answer 1

As per your example, try:

Sub HTH
    With Sheet2.Range("A2:A" & Sheet2.Cells(Rows.Count, 2).End(xlUp).Row)
        .Formula = Replace("=LOOKUP(2,1/(Sheet1!C$2:C$x=C2)/(Sheet1!B$2:B$x=B2),Sheet1!A$2:A$x)", _
            "x", (Sheet1.UsedRange.Rows.Count - 1))
        .Value = .Value
    End With
End Sub

It will probably be more efficient to update the SQL query.

To open the VBA editor press Alt-F11.

Here is a screenshot of the code in the VBA editor with the code sample, click the green play button to run the code:

Based on the additional info you may want to try this alternative procdure:

Sub HTH2()
    Dim vSource As Variant
    Dim vOutput As Variant
    Dim sKey As String

    vSource = Sheet1.UsedRange.Resize(, 3).Value
    vOutput = Sheet2.UsedRange.Resize(, 3).Value

    With CreateObject("Scripting.Dictionary")
        For lloop = 1 To UBound(vSource, 1)
            .Add vSource(lloop, 2) & ":" & vSource(lloop, 3), vSource(lloop, 1)
        Next lloop

        For lloop = 1 To UBound(vOutput, 1)
            sKey = vOutput(lloop, 2) & ":" & vOutput(lloop, 3)
            If .exists(sKey) Then
                vOutput(lloop, 1) = .Item(sKey)
            Else
                vOutput(lloop, 1) = ""
            End If
        Next lloop
    End With

    Sheet2.Range("A1").Resize(UBound(vOutput, 1), 1).Value = vOutput

End Sub