Question

I have 2 tables, Driver and Mechanic and in both table they have a same column Employee#

How do i check both tables using PL/SQL so that an employee in Driver table cannot appear in the Mechanic table by comparing the employee#. And if it happens, it would display a message “Employee# cant be both driver and mechanic!”

I do know that i could simply just compare both table using:

SELECT Employee#
FROM Driver
INTERSECT
SELECT Employee#
FROM Mechanic

But its a requirement for me to use PL/SQL.

I’ve tried using cursor but i cant seem to make it run through the entire column. Here are my code:

declare
cursor c1 is select employee# from driver;
cursor c2 is select employee# from mechanic;
driverenum number(30);
mechanicenum number(30);
begin
open c1;
fetch c1 into driverenum;
close c1;
open c2;
fetch c2 into mechanicenum;
close c2;
if driverenum in (mechanicenum) then
dbms_output.put_line(driverenum);
end if;
end;
/                                                                      

Answer 1

If the only requirement is that you use PL/SQL

DECLARE
  TYPE emp_nt IS TABLE OF driver.employee#%type;

  l_drivers   emp_nt;
  l_mechanics emp_nt;
  l_both      emp_nt;
BEGIN
  SELECT employee#
    BULK COLLECT INTO l_drivers
    FROM driver;

  SELECT employee#
    BULK COLLECT INTO l_mechanics
    FROM mechanic;

  l_both := l_drivers MULTISET INTERSECT l_mechanics;

  FOR i IN 1 .. l_both.count
  LOOP
    dbms_output.put_line( 'Employee ' || l_both(i) || 
                            ' is employed as both a driver and a mechanic' );
  END LOOP;
END;

This approach would potentially occupy quite a bit of space in the PGA if there are a large number of rows in either table. But normally it would be almost as efficient as the SQL solution.