Question

I have 20 checkboxes.

This is the event for the checkbox nº1 :

Public Sub C1CheckBox1_CheckedChanged(sender As Object, e As EventArgs) Handles C1CheckBox1.CheckedChanged
    If C1CheckBox1.Checked = True Then My.Settings.box1_selected = "Y" Else My.Settings.box1_selected = "N"
    Dim checkedpath1 = C1CheckBox1.Text
End Sub

I know I can add all the checkboxes in the "handles", but my number of checkboxes is undetermined and this is what I want to do:

(Pseudocode)

Public Sub ALL_THE_CHECKBOXES_CheckedChanged(sender As Object, e As EventArgs) Handles ALL_THE_CHECKBOXES.CheckedChanged
    If ANY_CHECKBOX.Checked = True
        My.Settings.boxNUMBER_OF_THIS_SELECTED_CHECKBOX_selected = "Y"
    Else 
        My.Settings.boxNUMBER_OF_THIS_SELECTED_CHECKBOX_selected = "N"
    End If
    Dim checkedpathNUMBER_OF_THIS_SELECTED_CHECKBOX = C1CheckBoxNUMBER_OF_THIS_SELECTED_CHECKBOX.Text
End Sub

I need to generate a event that handles an undetermined number of checkboxes,
I need to do the same action if any of the checkboxes is selected, but only in that selected checkbox.

Basically I want to remember in the settings which checkboxes was selected and which not…

UPDATE:

At form load I create ALL the form checkboxes with this code:

Public Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim List As Integer = 0
    Dim posy As Integer = 10

    filesystem = CreateObject("Scripting.FileSystemObject")
    ThisDir = filesystem.GetFolder(My.Settings.folderpath)

    For Each folder In ThisDir.Subfolders
        List = List + 1
        posy = posy + 20

        Dim newCheckBox As New CheckBox()
        Panel1.Controls.Add(newCheckBox)
        newCheckBox.Name = "checkbox" & List.ToString()
        newCheckBox.Text = folder.name
        newCheckBox.Location = New Point(10, posy)
    Next
End Sub

That creates a checkboxes named "checkbox1", "checkbox2", "checkbox3", etc…

Answer 1

All checkboxes are inside of another control. might be form, panel whatever. So you can cycle through these checkboxes and manually assign the eventhandler for each checkbox you find

Revised Sample code:

You need a setting of type StringCollection named MyCBs – or you can use whatever name you like, just make the necessary changes to the code.

Private Sub Form1_FormClosing(sender As Object, e As FormClosingEventArgs) Handles Me.FormClosing
    My.Settings.Save()
End Sub

Private Sub AnyCB_CheckedChanged(sender As Object, e As EventArgs)

    Dim cb = DirectCast(sender, CheckBox)
    If cb.Checked AndAlso Not My.Settings.MyCBs.Contains(cb.Name) Then
        My.Settings.MyCBs.Add(cb.Name)
    ElseIf Not cb.Checked AndAlso My.Settings.MyCBs.Contains(cb.Name) Then
        My.Settings.MyCBs.Remove(cb.Name)
    End If

End Sub

Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown

    If My.Settings.MyCBs Is Nothing Then My.Settings.MyCBs = New Collections.Specialized.StringCollection

    For Each s In My.Settings.MyCBs
        DirectCast(Me.Controls(s), CheckBox).Checked = True
    Next

    For Each cb In Me.Controls.OfType(Of CheckBox)()
        AddHandler cb.CheckedChanged, AddressOf AnyCB_CheckedChanged
    Next

End Sub

This sample saves the checked status of the checkboxes in my.settings inside a StringCollection. If a CB is checked it’s name is added to the collection, if it’s unchecked, it’s name is removed. This means on startup you can simply check which CB name is in the collection and sets its checked stats to true. Finally you use AddHandler to execute the code for any CB contained in your Form.
Note that there’s NO error handling inside the code, which means that this is your part …