Question

I have 250 Microsoft Excel (.xls) files, all in a folder. I need to do the following:

for each file:
    open the file
    switch to a specific tab in the file
    extract the text from rows 15-100 on that tab
    save the text in a text file somewhere

I assume this can be automated somehow, but I have no idea how. Where do I start looking to figure out how to do this? I really don’t want to open 250 excel files and copy text out by hand, as that would take hours. 🙁

Answer 1

Since you already have Excel, you can create an Excel macro in a separate worksheet to do this; just make sure the worksheet is outside of the directory you are parsing. You’ll need to add a reference for the FileSystemObject, which should be found in C:\Windows\System32\scrrun.dll.

Option Explicit

Sub ExtractData()
    Dim fso As New FileSystemObject
    Dim oFile As File
    Dim oFolder As Folder

    Dim sFileOutput As String
    Dim fNum

    Dim excelFile As Excel.Workbook
    Dim excelWorksheet As Excel.Worksheet
    Dim i As Integer

    sFileOutput = "C:\FolderToScan\ExcelOutput.txt"

    Set oFolder = fso.GetFolder("C:\FolderToScan")

    For Each oFile In oFolder.Files
        If Right(oFile.Name, 3) = "xls" Then
            fNum = FreeFile()
            Open sFileOutput For Append As fNum

            Set excelFile = Workbooks.Open(oFile.Path)

            Set excelWorksheet = excelFile.Sheets(1)
            'Or:
            ' Set excelWorksheet = excelFile.Sheets("Name of your sheet")

            For i = 15 To 100
                Write #fNum, excelWorksheet.Cells(i, 1)
            Next
            Close #fNum

            excelFile.Close
            Set excelFile = Nothing
        End If
    Next
End Sub