Question

I have a 2 collection of varying objects.

Let’s say I have the following two objects

Private col1 as Collection(Of A) and Private col2 as Collection(Of B)

But object of Type A has a collection of Type B as an Attribute.

so A looks like that

Public Class A
    Public Property myStringProp() as string
    Public Property colB() as Collection(Of B)
End Class

whereas B looks like

Public Class B
    Public Property myStringProp() as string
End Class

So in col2 i can have e.g. 20 items of Type B.
In col1 I have e.g. 2 items of Type A. Each of them has n references to items of Type B to the collection of col2.

How can I serialize and deserialize these Objects so that the references will be restored when deserializing?

Preferred Serialization with XML.

I have tried to use the DataContractSerializer but I have no idea where and how to use it.

Edit:

OK. I would be able to resolve them manually. But I don’t like the way:

  For Each itema As A In col1
     For Each itemb As B In itema.colB
        For Each objB In col2
           If itemb.myStringProp = objB.myStringProp Then
              itemb = objB
           End If
        Next
     Next
  Next

This would just loop through all objects of A in col1 and then loop through all objects of B and search an object in col2 with the same value for myStringProp.

So any cleaner solution would be appreciated 🙂

So any cleaner solutions?

Answer 1

The serializer can preserve object references in a single serialization episode. So if you have both collections as members of a single object (which is then serialized / deserialized), you can use the preserveObjectReferences parameter in the DataContractSerializer constructor, and you’ll get that. Another option is to decorate the type with <DataContract(IsReference:=True)>, which can also be used to preserve the references. The code below shows the first approach.

Public Class StackOverflow_8387789
    Public Class A
        Public Property myStringProp() As String
        Public Property colB() As Collection(Of B)
    End Class

    Public Class B
        Public Property myStringProp() As String
    End Class

    Public Class Both
        Public Property col1 As Collection(Of A)
        Public Property col2 As Collection(Of B)
    End Class

    Public Shared Sub Test()
        Dim both = New Both()
        both.col2 = New Collection(Of B)
        both.col2.Add(New B With {.myStringProp = "B1"})
        both.col2.Add(New B With {.myStringProp = "B2"})
        both.col2.Add(New B With {.myStringProp = "B3"})
        both.col1 = New Collection(Of A)
        Dim colBForA1 = New Collection(Of B)
        colBForA1.Add(both.col2(0))
        colBForA1.Add(both.col2(1))
        Dim colBForA2 = New Collection(Of B)
        colBForA2.Add(both.col2(1))
        colBForA2.Add(both.col2(2))
        both.col1.Add(New A With {.myStringProp = "A1", .colB = colBForA1})
        both.col1.Add(New A With {.myStringProp = "A2", .colB = colBForA2})
        Dim dcs = New DataContractSerializer(GetType(Both), Nothing, Integer.MaxValue, False, True, Nothing)
        Dim ms = New MemoryStream()
        Dim ws = New XmlWriterSettings With { _
                .Encoding = Encoding.UTF8,
                .Indent = True,
                .IndentChars = "  ",
                .OmitXmlDeclaration = True
            }
        Dim xw = XmlWriter.Create(ms, ws)
        dcs.WriteObject(xw, both)
        xw.Flush()
        Console.WriteLine("Serialized: {0}", Text.Encoding.UTF8.GetString(ms.ToArray()))

        ms.Position = 0
        Console.WriteLine("Now deserializing:")
        Dim both2 = CType(dcs.ReadObject(ms), Both)
        Console.WriteLine("Is both.col1(0).colB(0) = both.col2(0)? {0}", both2.col1(0).colB(0) Is both2.col2(0))
        Console.WriteLine("Is both.col1(1).colB(1) = both.col2(2)? {0}", both2.col1(1).colB(1) Is both2.col2(2))
        Console.WriteLine("Is both.col1(0).colB(0) = both.col2(2) (should be False)? {0}", both2.col1(0).colB(0) Is both2.col2(2))
    End Sub
End Class