Question

I have a “black box” excel model with 1 sheet. It has 2 inputs, which are named ranges “Input1” and “Input2”, and one output, which is a named range “Output”. I wrote a macro to test the sensitivity of this model to variations in it’s inputs, but I was wondering if there was a more elegant way to do this:

Sub LoopMacro()

Dim outrow As Integer
outrow = 1

For i = 1 To 10 Step 0.5
    Range("Input1").Value = i

    For j = 1 To 10 Step 0.5
        Range("Input2").Value = j

        Output outrow
        outrow = outrow + 1

    Next j
Next i
End Sub

Sub Output(outrow As Integer)

Sheets("Output").Cells(outrow, 1) = Range("Input1").Value
Sheets("Output").Cells(outrow, 2) = Range("Input2").Value
Sheets("Output").Cells(outrow, 3) = Range("Output").Value

End Sub

The problem with this macro is that it requires a for loop for each input variable, and would get rather tedious if I had more than a few inputs. I’m trying to figure out if there’s a way to code this such that I can define n inputs (named ranged “Input1”, “Input1”, to “Inputn”), along with their min and max values, and have the macro automatically loop through the relevant values of Input1-Inputn

Answer 1

Not sure, but this may be what you’re looking for: just modify the arrays which contain the parameter names and value ranges.

Sub TestModelInputs()

    Dim shtModel As Worksheet, shtResults As Worksheet
    Dim arrNames, arrMin, arrMax, arrStep, arrVals, x
    Dim rw As Long, lb, ub, n, incr As Boolean

    '###modify input parameters here
    arrNames = Array("Input1", "Input2", "Input3")
    arrMin = Array(1, 1, 1)
    arrMax = Array(4, 5, 6)
    arrStep = Array(1, 1, 1)
    '###done with parameter setup

    Set shtModel = ThisWorkbook.Sheets("Model")
    Set shtResults = ThisWorkbook.Sheets("Results")

    rw = 1
    arrVals = arrMin
    lb = LBound(arrNames)
    ub = UBound(arrNames)
    n = (ub - lb) + 1
    shtResults.UsedRange.ClearContents

    Do             
        rw = rw + 1
        For x = lb To ub
            shtModel.Range(arrNames(x)).Value = arrVals(x)
        Next x

        With shtResults.Rows(rw)
            .Cells(1).Resize(1, n).Value = arrVals
            .Cells(n + 1).Value = shtModel.Range("Output").Value
        End With

        For x = lb To ub
            If arrVals(x) < arrMax(x) Then
                arrVals(x) = arrVals(x) + arrStep(x)
                Exit For
            Else
                If x = ub Then
                    Exit Do
                Else
                    arrVals(x) = arrMin(x)
                End If
            End If
        Next x
    Loop

End Sub