Question

I have a bug I’ve been trying to track down for a few weeks now, and have pretty much isolated exactly what’s going wrong. However, why this happens is beyond me.

I have a very large Oracle package (around 4,100 lines of code) and I’m calling several procedures. However, data seems to be getting lost between procedure calls.

The data that is being lost is:

dpmethodstate varchar_state_local_type;

First, I call this procedure:

PROCEDURE delivery_plan_set_state (
   messages OUT ReferenceCursor,
   state IN varchar_state_local_type
) AS
BEGIN
   logMessage('state COUNT is: ' || state.COUNT);
   dpmethodstate := state;
   FOR I IN 1..dpmethodstate.COUNT LOOP
      logMessage(dpmethodstate(I));
   END LOOP;
   logMessage('delivery_plan_set_state end - dpmethodstate count is now ' || dpmethodstate.COUNT);
   OPEN messages FOR SELECT * FROM TABLE(messageQueue);
   messageQueue := NULL;
END delivery_plan_set_state;

I pass in state, which is a valid array of a single string. I can verify in the logs that dpmethodstate has a COUNT of 1 when the procedure ends.

Next, I call the execute_filter procedure which looks like this:

PROCEDURE execute_filter (
   --Whole bunch of OUT parameters
) AS
--About 50 different local variables being set here
BEGIN
   SELECT TO_CHAR(SYSTIMESTAMP, 'HH24:MI:SS.ff') INTO TIMING FROM DUAL;
   logMessage('[' || TIMING || '] execute_filter begin');
   logMessage('a) dpmethodstate Count is: ' || dpmethodstate.COUNT);

   --Rest of procedure

However, this time dpmethodstate.COUNT is 0. The value I set from delivery_plan_set_state has vanished!

When I look at my logs, it looks something like this:

proposed
delivery_plan_set_state end - dpmethodstate count is now 1
[21:39:48.719017] execute_filter begin
a) dpmethodstate Count is: 0

As you can see, dpmethodstate got lost between procedure calls. There’s a few things to note:

1. Nothing else in this package is capable of setting the value for dpmethodstate besides delivery_plan_set_state. And I can see nothing else has called it.
2. My client side code is written in C#, and not much happens between the two procedure calls.
3. This happens perhaps 1 out of every 100 times, so it’s very difficult to track down or debug.

First off, what’s the best way to debug a problem like this? Is there any more logging I can do? Also, how does Oracle maintain state between procedure calls and is there anything that can intermittently reset this state? Any pointers would be much appreciated!

Answer 1

Is dpmethodstate a package global variable? I’m assuming it is, but I don’t see that explicitly mentioned.

Since package global variables have session scope, are you certain that the two procedure calls are always using the same physical database connection and that nothing is using this connection in the interim? If you’re using some sort of connection pool where you get a connection from the pool before each call and return the connection to the pool after the first call, it wouldn’t be terribly unusual in a development environment (or low usage environment) to get the same connection 99% of the time for the second call but get a different session 1% of the time.

Can you log the SID and SERIAL# of the session where you are setting the value and where you are retrieving the value?

SELECT sid, serial#
  FROM v$session
 WHERE sid = sys_context( 'USERENV', 'SID' );

If those are different, you wouldn’t expect the value to persist.

Beyond that, there are other ways to clear session state but they require someone to take explicit action. Calling DBMS_SESSION.RESET_PACKAGE or DBMS_SESSION.MODIFY_PACKAGE_STATE(DBMS_SESSION.REINITIALIZE) will clear out any session state set in your session. Compiling the package will do the same thing but that should throw an error warning you that your session state was discarded when you try to read it.